Print the command line to screen and then execute it. Useful when you want to have echo turned off everywhere else, and not speckle code with `echo on && {cmd line here} && @echo off`

run.bat

@echo off
:: --- Run.bat ---
:: Echo the command line to screen and then execute it.
::
:: Useful when you want to have echo turned off everywhere else,
:: and not speckle code with `echo on && {cmd line here} && @echo off`
if "%*"=="" goto :Usage
setlocal
echo === Run =================
set _cmd=%*
echo %_cmd%
call %_cmd%
if not %errorlevel%==0 (echo. && echo *** Non-zero exit code: %errorlevel%)
echo =========================
endlocal
goto :eof

:Usage
  echo.
  echo. Usage:  %~n0 [command] {parameters}
  echo.
  goto :eof

runner_function.bat

@echo off
call :run [command -par1 -par2 in_thing out_thing]
goto :eof
:: ---------------------------------------------------------------------------
:run
  :: Echo the command line to screen and then execute it.
  ::
  :: Useful when you want to have echo turned off everywhere else,
  :: and not speckle code with `echo on && {cmd line here} && @echo off`
  setlocal
  set _cmd=%*
  echo %_cmd%
  %_cmd%
  if not %errorlevel%==0 (echo. && echo *** Exit code: %errorlevel% && echo.)
  endlocal
  goto :eof