ctemplate PKGBUILD and patch

PKGBUILD

pkgname=ctemplate
pkgver=2.3
pkgrel=2
pkgdesc="A library implementing a simple but powerful template language for C++"
arch=('i686' 'x86_64')
url="http://code.google.com/p/ctemplate/"
license=('BSD')
makedepends=('subversion' 'python2')
depends=('gcc-libs' 'perl')
source=(svn+http://$pkgname.googlecode.com/svn/tags/$pkgname-$pkgver/
        python2.patch)
sha256sums=('SKIP'
            '51287e5043aaf8ea87dcf3f824ec8b92dceeafc74552abf32a447b38c3b12f13')

prepare() {
  cd "$srcdir/$pkgname-$pkgver"

  patch -p1 < "$srcdir/python2.patch"
}

build() {
  cd "$srcdir/$pkgname-$pkgver"

  ./configure --prefix=/usr
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"

  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

python2.patch

diff -ur a/src/htmlparser/fsm_config.py b/src/htmlparser/fsm_config.py
--- a/src/htmlparser/fsm_config.py	2014-05-08 14:18:41.000000000 +0200
+++ b/src/htmlparser/fsm_config.py	2014-05-17 20:36:31.704608195 +0200
@@ -1,4 +1,4 @@
-#!/usr/bin/env python
+#!/usr/bin/env python2
 #
 # Copyright (c) 2008, Google Inc.
 # All rights reserved.
diff -ur a/src/htmlparser/generate_fsm.py b/src/htmlparser/generate_fsm.py
--- a/src/htmlparser/generate_fsm.py	2014-05-08 14:18:41.000000000 +0200
+++ b/src/htmlparser/generate_fsm.py	2014-05-17 20:36:35.751227293 +0200
@@ -1,4 +1,4 @@
-#!/usr/bin/env python
+#!/usr/bin/env python2
 #
 # Copyright (c) 2008, Google Inc.
 # All rights reserved.