Rotate a bitmap data to account for image orientation

distriqt.camera.helper.applyOrientation

function applyOrientation( bitmapData:BitmapData, orientation:String ) :BitmapData
{
	/*
		1) transform="";;
		2) transform="-flip horizontal";;
		3) transform="-rotate 180";;
		4) transform="-flip vertical";;
		5) transform="-transpose";;
		6) transform="-rotate 90";;
		7) transform="-transverse";;
		8) transform="-rotate 270";;
	*/  

	var w:int = bitmapData.width;
	var h:int = bitmapData.height;
	var scaleX:Number = 1;
	var scaleY:Number = 1;
	var rotateAngle:Number = 0;
	
	switch (orientation)
	{
		default:
		case "1":
			break;
		
		case "2":
			scaleX = -1;
			break;
		
		case "3":
			rotateAngle = Math.PI;
			break;
		
		case "4":
			scaleY = -1;
			break;
		
		case "5":
			break;
		
		case "6":
			w = bitmapData.height;
			h = bitmapData.width;
			rotateAngle = Math.PI / 2;
			break;
		
		case "8":
			w = bitmapData.height;
			h = bitmapData.width;
			rotateAngle = -Math.PI / 2;
			break;
	
	}
	
	var matrix:Matrix = new Matrix();
	matrix.translate( - bitmapData.width * 0.5, - bitmapData.height * 0.5 );
	matrix.scale( scaleX, scaleY );
	matrix.rotate( rotateAngle );
	matrix.translate( w * 0.5, h * 0.5 );
	
	var result:BitmapData = new BitmapData( w, h );
	result.draw( bitmapData, matrix );
	return result;
}
// com.distriqt.Camera

http://airnativeextensions.com/extension/com.distriqt.Camera