ib2019-pw-prot-ex

PREFIX bk: <http://www.ondex.org/bioknet/terms/>
PREFIX bkr: <http://www.ondex.org/bioknet/resources/>
PREFIX bka: <http://www.ondex.org/bioknet/terms/attributes/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX agri: <http://agrischemas.org/>
PREFIX bioschema: <http://bioschemas.org/>
PREFIX schema: <http://schema.org/>

SELECT DISTINCT ?pmedId ?pubTitle ?authorsList ?pubYear ?proteinName ?path ?pub
WHERE {
  ?path a bk:Path.
  ?react bk:part_of ?path.
  ?react a bk:Reaction.
  ?react bk:ca_by|bk:in_by ?enzyme.
  ?protein bk:is_a ?enzyme.
  
  ?path bk:prefName ?pathName.
  
  FILTER ( REGEX ( ?pathName, 'oxygenic photosynthesis', 'i' ) )
  
  ?protein bk:pub_in ?pub.

  OPTIONAL { ?protein bk:prefName ?proteinName }

  
  ?pub a bk:Publication;
    bk:prefName ?pmedId;
	bka:AbstractHeader ?pubTitle;
	bka:AUTHORS ?authorsList.
  
  OPTIONAL { ?pub bka:YEAR ?pubYear }
}
ORDER BY DESC ( ?pubYear ) ?pub ?proteinName