Create SVG percentiles graph from tab-separated value (TSV) file with gnuplot

data.tsv

percentiles.plt

set terminal svg enhanced size 1200 600 font "Helvetica,20" name "Response_Time_Percentiles"
set border 31 linewidth .3
set output "percentiles.svg"
set title "Response Time Percentiles 2021-06-11"
set xlabel "Time"
set ylabel "Duration (ms)"
set tics font "Helvetica,13"
set ytics 1000
set grid ytics
set xdata time
set format x "%a\n%Y-%m-%d\n%H:%M\nUTC"   # time format used in output
set timefmt '%Y-%m-%dT%H:%M:%SZ' # format of timestamps in input file
#set xrange ['2021-06-11T00:00:00Z':'2021-06-11T12:00:00Z'] # define time interval to be used 
plot "data.tsv" using 1:2 pt 1 ps .3 with lines title 'p50',\
     "data.tsv" using 1:3 pt 1 ps .1 with lines title 'p75',\
     "data.tsv" using 1:4 pt 1 ps .1 with lines title 'p90'

plot-graph.sh

#!/bin/sh

# aggregate response time data into ten-minute groups, compute percentiles 50/75/90 and render data with gnuplot 
# requires gnuplot (for rendering); cat, cut, sort, java (11+) for generating data.tsv
# created 2021-08-17

# for LogProcessor see https://gist.github.com/marco-schmidt/78f86aa595306535fd51ea30ce823c5c
# that repository also contains LogGenerator.java used to create input file 2021-06-11.log
# that file contains lines like this (ISO 8601 timestamp + tab + integer number):
# 2021-06-11T00:00:00.985Z	4688

# http://www.gnuplot.info
# brew install gnuplot

# aggregate data and generate data.tsv
# cut throws out the second column with the number of elements per group
#cat ../LogProcessor/2021-06-11.log|java ../LogProcessor/LogProcessor.java - -g 600000 -p 50,75,90|cut -f 1,3,4,5|sort > data.tsv

# render SVG file
gnuplot percentiles.plt

# open percentiles.svg in web browser or other SVG viewer