ByteArray Segmentation

gistfile1.as

class ByteArrayHelper
{

    public static function getSegments(source : ByteArray, size: int = 1000) : Array
    {
        var result : Array = [];

        if(!source)
        {
            return result;
        }

        var index : int = 0;
        var total : int = Math.ceil(source.length / size);

        while(index < total)
        {
            var sendBytes : ByteArray = new ByteArray();

            source.position = index * size;
            var currentLength : int =  Math.min(size, source.bytesAvailable);

            sendBytes.writeBytes(source, source.position, currentLength);
            index++;
            result.push(sendBytes);
        }
        return result;
    }

    public static function mergeSegments(segments : Array) : ByteArray
    {
        var result : ByteArray = new ByteArray();
        for each (var segment : ByteArray in segments)
        {
            result.writeBytes(segment);
        }

        result.position = 0;
    	return result;
    }
}

cuts ByteArray into segments of given length.if you have to transfer a huge amount of data via external interface, this is pretty handy