Jogo de caça-palavras aleatório.

cpl.pl6

#!/usr/bin/perl6

use v6;

# caça-palavras em P6

"Só um outro jogo de caça-palavras...".say;
"Diga o número de === colunas ~ linhas ===.".say;
my $limite  = prompt "Qual o limite que você quer?" ~ " ";
my @numeros = ^$limite;
my @letras  = 65 .. 90; # De A a Z
my @matriz;

for @numeros -> $linha {
	@matriz[$linha] = (@letras.pick($limite))>>.chr; # Gera letras aleatórias
}

@matriz>>.say; # Mostra a tabela
my $palavra   = prompt "Qual palavra você quer buscar?" ~ " ";
my $invertida = $palavra.flip;

for @numeros -> $linha {
	# Procura a palavra pelas linhas
	given @matriz[$linha].join {
		"Encontrou a palavra $palavra na linha { $linha.succ }.".say and last
		        when /$palavra/;
		"Encontrou como '$invertida' na linha { $linha.succ }.".say and last
		        when /$invertida/;
	}
}

for @numeros -> $coluna {
	# Procura a palavra pelas colunas
	given @matriz>>[$coluna].join {
		"Encontrou a palavra $palavra na coluna { $coluna.succ }.".say and last
			when /$palavra/;
		"Encontrou como '$invertida' na coluna { $coluna.succ }.".say and last
			when /$invertida/;

	}
}

# fim do script