Praticando conceitos iniciais de programação com Portugol. Como Variáveis, Entrada e Saída, Comandos de condição, Operadores relacionais e as Funções Aritméticas do VisualG :)

FUNCOES ARITMETICAS.ALG

Algoritmo "Funcoes Aritmeticas"
// Autor(a)    : Mariana Lira
// Data atual  : 23/07/2021
Var
   n_inteiro: inteiro
   n_real: real

   n_negativo, v_absoluto: inteiro
   base, potencia: real
   expoente: inteiro
   parte_inteira: inteiro
   raiz: real
   p: real
   angulo, radiano, seno, cosseno, tangente: real
   
   operacao: caractere
   opcoes: inteiro

Inicio
// Opções
   opcoes <- 10
   
   escreval ("Qual destas Funções Aritméticas desejas utilizar?")
   escreval() // linha em branco
   escreval ("1. Módulo - abs")
   escreval ("2. Exponenciação - exp")
   escreval ("3. Parte inteira do número - int")
   escreval ("4. Raiz Quadrada - raizQ")
   escreval ("5. Pí - pi")
   escreval ("6. Graus para Radianos - graupRad")
   escreval ("7. Seno - sen")
   escreval ("8. Cosseno - cos")
   escreval ("9. Tangente - tan")
   escreval ("Digite 10 para cancelar o processo")
   escreval() // linha em branco
   
// "Selecionar" opção
   escreval ("Digite o número correspondente ou sua abreviação abaixo.")
   leia (operacao)
   escreval() // linha em branco

   // Instrução alternativa
   se operacao = "10" entao
      escreval ("Pressione ESC para sair")
   Fimse
   // Caso de erro
   se Caracpnum(operacao) > opcoes entao
      escreval ("Opa, não entendi. Tente novamente, mais tarde")
   Fimse

// Usando Abs()
   se ((operacao = "1") OU (operacao = "abs")) entao
      escreval("Operação com a função de módulo selecionado")
      escreval()

      escreva ("Digite um número negativo: ")
      leia (n_negativo)

      v_absoluto <- Abs(n_negativo)
      
      se n_negativo = v_absoluto entao // n_negativo > 0
         escreval()
         escreval ("Você digitou um número positivo!")
         escreval ("O módulo de", n_negativo," é ele mesmo")
      senao
           escreval()
           escreval ("O módulo de", n_negativo," é", v_absoluto)
      Fimse
      
   Fimse
   
// Usando Exp()
   se ((operacao = "2") OU (operacao = "exp")) entao
      escreval("Operação com a função de exponenciação selecionado")
      escreval()

      escreva ("Digite o valor da base: ")
      leia (base)

      escreva ("Digite o valor do expoente: ")
      leia (expoente)

      potencia <- Exp(base,expoente)

      escreval ("A potência de", base," elevado a", expoente," é",potencia)
   Fimse
   
// Usando Int()
   se ((operacao = "3") OU (operacao = "int")) entao
      escreval("Operação com a função de parte inteira selecionado")
      escreval()

      escreva ("Digite um número real: ")
      leia (n_real)

      parte_inteira <- Int(n_real)

      escreval ("O número real", n_real,"é ", parte_inteira,"retirando sua parte decimal")
   Fimse
   
// Usando RaizQ()
   se ((operacao = "4") OU (operacao = "raizQ")) entao
      escreval("Operação com a função de raiz quadrada selecionado")
      escreval()
      
      escreva ("Digite um número natural: ")
      leia (n_inteiro)
      
      se n_inteiro < 0 entao // verifica se o número é negativo
         escreval()
         escreval ("Ei, esse é um número negativo, assim não vale")
      senao
           raiz <- RaizQ(n_inteiro)
           
           se raiz <> Int(raiz) entao // verifica se é um número decimal
              escreval()
              escreval ("A raiz quadrada de", n_inteiro," não é exata")
              escreval ("Sua parte inteira é", Int(raiz)," de", raiz)
           senao
                escreval()
                escreval ("A raiz quadrada de", n_inteiro," é", raiz)
           Fimse
           
      Fimse
   Fimse
   
// Usando Pi
   se ((operacao = "5") OU (operacao = "pi")) entao
      escreval("Operação com a função de Pí selecionado")
      escreval()
      
      p <- Pi
      
      escreval ("Usar Pi no VisualG retorna", p)
   Fimse
   
// Usando GraupRad()
   se ((operacao = "6") OU (operacao = "graupRad")) entao
      escreval("Conversão de graus para radianos selecionado")
      escreval()

      escreva ("Digite um ângulo: ")
      leia (angulo)

      radiano <- GraupRad(angulo)

      escreval()
      escreval ("O ângulo de", angulo,"° é igual a", radiano," radianos")
   Fimse

// Usando Sen()
   se ((operacao = "7") OU (operacao = "sen")) entao
      escreval("Operação com a função de seno selecionado")
      escreval()
      
      escreva ("Digite um ângulo: ")
      leia (angulo)

      seno <- Sen(GraupRad(angulo))
      
      escreval()
      escreval ("O seno de", angulo,"° é igual a", seno)
   Fimse
   
// Usando Cos()
   se ((operacao = "8") OU (operacao = "cos")) entao
      escreval("Operação com a função de cosseno selecionado")
      escreval()
      
      escreva ("Digite um ângulo: ")
      leia (angulo)
      
      cosseno <- Cos(GraupRad(angulo))
      
      escreval()
      escreval ("O cosseno de", angulo,"° é igual a", cosseno)
   Fimse

// Usando Tan()
   se ((operacao = "9") OU (operacao = "tan")) entao
      escreval("Operação com a função de tangente selecionado")
      escreval()

      escreva ("Digite um ângulo: ")
      leia (angulo)

      tangente <- Tan(GraupRad(angulo))

      escreval()
      escreval ("A tangente de", angulo,"° é igual a", tangente)
   Fimse

Fimalgoritmo