gistfile1.txt

buildscript {
    repositories {
        maven { url 'https://maven.fabric.io/public' }
    }

    dependencies {
        classpath 'io.fabric.tools:gradle:1.24.3'
    }
}
apply plugin: 'com.android.application'
apply plugin: 'io.fabric'
apply plugin: 'com.neenbedankt.android-apt'
apply plugin: 'me.tatarka.retrolambda'

repositories {
    jcenter()
    maven { url 'https://maven.fabric.io/public' }
    maven {
        url "https://jitpack.io"
    }
}

android {
    compileSdkVersion 25
    buildToolsVersion '25.0.3'

    defaultConfig {
        applicationId 'com.nokl.androidclient'
        minSdkVersion 16
        targetSdkVersion 25
        versionCode 1
        versionName "0.9.18"
        archivesBaseName = "nokl"
        vectorDrawables.useSupportLibrary = true
        ndk {
            moduleName "filesyslib"
            abiFilters "armeabi", "armeabi-v7a", "x86"
        }
        testInstrumentationRunner "android.support.test.runner.AndroidJUnitRunner"
    }

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }

    sourceSets {
        main {
            manifest.srcFile 'AndroidManifest.xml'
            java.srcDirs = ['../src']
            resources.srcDirs = ['../src']
            aidl.srcDirs = ['../src']
            renderscript.srcDirs = ['../src']
            res.srcDirs = ['../res']
            assets.srcDirs = ['../assets']
            jni.srcDirs.add('../../../sib-lib')
            jni.srcDirs.add('../../../openssl/openssl/include/openssl')
            jni.srcDirs.add('../../')
            jni.srcDirs.add('../jni')
            jniLibs.srcDir '../obj/local'
        }
    }

    buildTypes {
        release {
            externalNativeBuild {
                ndkBuild {
                    cFlags.add("-DRELEASE")
                    cFlags.add("-O2")
                    cppFlags.add("-Wno-reorder")
                    cppFlags.add("-std=c++11")
                    arguments.add("V=1")
                    arguments.add("APP_DEBUG=false")
                    arguments.add("NDK_DEBUG=0")
                    arguments.add("NDK_OUT=../obj")
                    abiFilters "armeabi", "armeabi-v7a", "x86"
                }
            }
            minifyEnabled true
            jniDebuggable false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-project.txt'
            shrinkResources true;
        }
        debug {
            externalNativeBuild {
                ndkBuild {
                    cFlags.add("-D_DEBUG")
                    cFlags.add("-DDEBUG")
                    cFlags.add("-O0")
                    cppFlags.add("-Wno-reorder")
                    cppFlags.add("-std=c++11")
                    arguments.add("V=1")
                    arguments.add("APP_DEBUG=true")
                    arguments.add("NDK_DEBUG=1")
                    arguments.add("NDK_OUT=../obj")
                    abiFilters "armeabi", "armeabi-v7a", "x86"
                }
            }
            minifyEnabled false
            jniDebuggable true
        }
    }

    splits {
        abi {
            enable true
            reset()
            include 'x86', 'armeabi', 'armeabi-v7a'
//            universalApk true
        }
        // map for the version code. x86/mips must be higher than arm due to binary
        // code conversion libraries
        project.ext.versionCodes = [armeabi: 1, 'armeabi-v7a': 2, x86: 3]

        android.applicationVariants.all { variant ->
            // assign different version code for each output
            variant.outputs.each { output ->
                output.versionCodeOverride = project.ext.versionCodes.get(output.getFilter(com.android.build.OutputFile.ABI), 0) * 1000000 + android.defaultConfig.versionCode
            }
        }
    }

    externalNativeBuild {

        ndkBuild {
            path "../jni/Android.mk"
        }
    }


    aaptOptions {
        cruncherEnabled = false
    }

    packagingOptions {
        exclude 'META-INF/LICENSE'
        exclude 'META-INF/NOTICE'
    }
}

crashlytics {
    enableNdk true
    androidNdkOut '../obj'
    androidNdkLibsOut '../obj/local'
}

dependencies {
    compile 'com.android.support:appcompat-v7:25.3.1'
    compile 'com.android.support:cardview-v7:25.3.1'
    compile 'com.android.support:design:25.3.1'
    compile 'com.android.support:preference-v14:25.3.1'
    compile project(':siblibandroidjava')
    compile('com.crashlytics.sdk.android:crashlytics:2.6.8@aar') {
        transitive = true;
    }
    compile('com.crashlytics.sdk.android:crashlytics-ndk:1.1.6@aar') {
        transitive = true;
    }
    apt 'org.parceler:parceler:1.1.4'
    compile 'org.parceler:parceler-api:1.1.4'
    apt 'com.jakewharton:butterknife-compiler:8.2.1'
    apt 'com.google.dagger:dagger-compiler:2.6'
    apt 'com.hannesdorfmann.parcelableplease:processor:1.0.2'
    apt 'com.hannesdorfmann.fragmentargs:processor:3.0.2'
    compile 'com.jakewharton:butterknife:8.2.1'
    compile 'com.android.support:multidex:1.0.1'
    compile 'com.google.dagger:dagger:2.6'
    compile 'io.reactivex:rxandroid:1.1.0'
    compile 'io.reactivex:rxjava:1.2.2'
    compile 'com.artemzin.rxjava:proguard-rules:1.2.2.0'
    compile 'com.hannesdorfmann.parcelableplease:annotation:1.0.2'
    compile 'com.hannesdorfmann.fragmentargs:annotation:3.0.2'
    compile 'com.hannesdorfmann.fragmentargs:bundler-parceler:3.0.2'
    compile 'net.cachapa.expandablelayout:expandablelayout:2.3'
    compile 'com.google.code.gson:gson:2.7'
    compile 'com.github.chrisbanes:PhotoView:1.3.1'
    compile 'com.vincentbrison.openlibraries.android:dualcache:3.1.1'
    compile 'com.google.android.gms:play-services-appindexing:9.8.0'
    compile project(':ijkplayer-java')
    compile project(':ijkplayer-arm')
    compile project(':ijkplayer-armv7a')
    compile project(':ijkplayer-x86')
    androidTestCompile 'com.android.support:support-annotations:25.3.1'
    androidTestCompile 'com.android.support.test.espresso:espresso-core:2.2.2'
    androidTestCompile 'com.android.support.test.espresso:espresso-intents:2.2.2'
    androidTestCompile ('com.android.support.test.espresso:espresso-contrib:2.2.2'){
        exclude module: 'support-annotations'
        exclude module: 'support-v4'
        exclude module: 'support-v13'
        exclude module: 'recyclerview-v7'
        exclude module: 'design'
    }
    androidTestCompile 'com.android.support.test.uiautomator:uiautomator-v18:2.1.2'
    androidTestCompile'com.android.support.test:runner:0.5'
    androidTestCompile 'com.android.support.test:rules:0.5'
    androidTestCompile 'junit:junit:4.12'
    compile 'com.nostra13.universalimageloader:universal-image-loader:1.9.5'
    compile 'com.arello-mobile:moxy:1.5.3'
    annotationProcessor 'com.arello-mobile:moxy-compiler:1.5.3'
    compile 'com.arello-mobile:moxy-android:1.5.3'
}