a.rkt

#lang racket

(require racket/include
         syntax/parse/define
         (for-syntax racket/syntax
                     racket/port
                     syntax/modread))

(define-simple-macro (require/sweet-exp-racket path)
  #:with modname (generate-temporary #'path)
  (begin
    (include/reader path (sweet-exp-racket-reader 'modname))
    (require 'modname)))

(begin-for-syntax
  ;; Symbol -> [Any InputPort -> Syntax]
  (define ((sweet-exp-racket-reader modname) src input)
    (cond
      [(port-closed? input) eof]
      [else
       (define stx
         (with-module-reading-parameterization
             (lambda ()
               (read-syntax src
                 (input-port-append #t
                   (open-input-string "#lang sweet-exp racket\n")
                   input)))))
       (close-input-port input)
       (syntax-parse stx
         [(module _ l . b)
          #`(module #,modname l . b)])])))

(require/sweet-exp-racket "./b.rkt")

b.rkt

; on purpose we don't set #lang sweet-exp racket
{2 + 3}