TClass.ImmediateMethods

gistfile1.pas

// Parses a classes vmtMethodTable and finds all `published` methods this class declares.
// Find all available functions by recusing up the hierarchy with .ClassParent
// Martok 2012 - Public Domain / CC0

  TMethodTable = array of record
    Code: Pointer;
    Name: String;
  end;

  TTest = class
  public
    class function ImmediateMethods: TMethodTable;
  end;

//...

class function TTest.ImmediateMethods: TMethodTable;
type
  PVMTEntry = ^TVMTEntry;
  TVMTEntry = packed record
    EntrySize: Word;
    Code: Pointer;
    Name: ShortString;
  end;
  PMethodTable = ^TMethodTable;
  TMethodTable = packed record
    Count: Word;
    Methods: array of TVMTEntry;
  end;
var
  pVMT: Pointer;
  vmt: PMethodTable;
  entry: PVMTEntry;
  i: integer;
begin
  SetLength(Result, 0);
  // "Self" in a class method already points to the MT, so we don't strictly need that,
  // but dereference the pointer anyway just to be sure the compiler did nothing weird
  pVMT:= Pointer(Cardinal(Self) + vmtMethodTable);
  vmt:= Pointer(PCardinal(pVMT)^);
  if Assigned(vmt) then begin
    SetLength(Result, vmt^.Count);
    entry:= @vmt^.Methods;
    for i:= 0 to vmt^.Count-1 do begin
      Result[i].Code:= entry^.Code;
      Result[i].Name:= entry^.Name;
      Inc(Cardinal(entry), entry^.EntrySize);
    end;
  end;
end;