draft psutil msys2 pkgbuild

PKGBUILD

# Maintainer: Mateusz Mikuła <mati865@gmail.com>

_pyname=psutil 
_realname=${_pyname}
pkgbase=mingw-w64-python-${_realname}
pkgname=("${MINGW_PACKAGE_PREFIX}-python2-${_realname}"  "${MINGW_PACKAGE_PREFIX}-python3-${_realname}")
pkgver=1
pkgrel=1
pkgdesc="A cross-platform process and system utilities module for Python (mingw-w64)"
arch=('any')
url="https://github.com/giampaolo/psutil"
license=('BSD')
makedepends=("${MINGW_PACKAGE_PREFIX}-python2"
             "${MINGW_PACKAGE_PREFIX}-python3"
             "${MINGW_PACKAGE_PREFIX}-python3-setuptools"
             "${MINGW_PACKAGE_PREFIX}-python2-setuptools")
options=('staticlibs' 'strip' '!debug')
source=("https://github.com/manuelnaranjo/psutil/archive/master.zip")
sha256sums=('668681b89d134184336704bbdb5c6e70b3e59b4dcc7b2b97fe0a0670d0e9e701')

prepare() {  
  cd "$srcdir"/  
  for builddir in python{2,3}-build; do  
    rm -rf $builddir | true
    cp -r "${_pyname}-master" "${builddir}"
  done  
}  
  
check() {  
  for pver in {2,3}; do  
    msg "Python ${pver} test for ${CARCH}"  
    cd "${srcdir}/python${pver}-build"  
    ${MINGW_PREFIX}/bin/python${pver} setup.py check
  done  
}

# Note that build() is sometimes skipped because it's done in 
# the packages setup.py install for simplicity if you can do so.
package_python3-psutil() {
  depends=("${MINGW_PACKAGE_PREFIX}-python3")

  cd "${srcdir}/python3-build"
  MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=" \
  ${MINGW_PREFIX}/bin/python3 setup.py install --prefix=${MINGW_PREFIX} \
    --root="${pkgdir}" --optimize=1

  install -Dm644 LICENSE "${pkgdir}${MINGW_PREFIX}/share/licenses/python3-${_realname}/COPYING"
}

package_python2-psutil() {
  depends=("${MINGW_PACKAGE_PREFIX}-python2")

  cd "${srcdir}/python2-build"
  MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=" \
  ${MINGW_PREFIX}/bin/python2 setup.py install --prefix=${MINGW_PREFIX} \
    --root="${pkgdir}" --optimize=1

  install -Dm644 LICENSE "${pkgdir}${MINGW_PREFIX}/share/licenses/python2-${_realname}/COPYING"
}

package_mingw-w64-i686-python2-psutil() {
  package_python2-psutil
}

package_mingw-w64-i686-python3-psutil() {
  package_python3-psutil
}

package_mingw-w64-x86_64-python2-psutil() {
  package_python2-psutil
}

package_mingw-w64-x86_64-python3-psutil() {
  package_python3-psutil
}