Lazy Clojure file-watch, re-parsing when file changes.

file-watch.clj

(defn parsed-file-delay
  "A delay that returns `(parse-fn (slurp file-path))` on each dereference,
  recalculating the return value only when `(.lastModified (io/file file-path))`
  changes.
  
  Useful if you don't need any sort of push notification when the file changes."
  [file-path parse-fn]
  (let [last-contents (atom {:modified -1 :contents nil})
        ^File f (io/file file-path)]
    (reify IDeref
      (deref [this]
        (let [{:keys [modified contents] :as prev} @last-contents
              last-mod (.lastModified f)]
          (if (= modified last-mod)
            contents
            (let [updated {:modified last-mod :contents (parse-fn (slurp f))}]
              (compare-and-set! last-contents prev updated)
              (recur))))))))
(comment
  (spit "watch-me.txt" "(+ 10 10)")

  (def evaluated-file
    (parsed-file-delay
      "watch-me.txt"
      (fn [x]
        (println "Evaling...")
        (-> x read-string eval))))

  @eval
  ; => Evaling...
  ;    20

  @eval
  ; => 20

  (spit "watch-me.txt" "(* 10 10)")
  @eval
  ; => Evaling...
  ;    100
)