Type-checking an API method in 20 lines of Clojure.

gistfile1.clj

(defmacro defapi [method metadata args & forms]
  `(defn ~method [& {:as named-params#}]
     ;; preprocess arguments
     (doseq [arg# '~args]
       (let [param# (get named-params# (keyword arg#))
             optional# (:optional (meta arg#))]
         ;; ensure all required arguments were provided
         (when (and (not optional#) (nil? param#))
           (throw (IllegalArgumentException.
                   (format "Argument \"%s\" is required and was not provided." (name arg#)))))

         ;; type-check arguments if they have been type-hinted
         (let [type# (resolve (:tag (meta arg#)))]
           (when (and (not (and optional# (nil? param#)))
                      (and type# (not (instance? type# param#))))
             (throw (IllegalArgumentException. (format "Expected \"%s\" to be of type %s (was %s)."
                                                       (name arg#) type# (type param#))))))))
     ;; set up the bindings
     (let [{:keys ~args} named-params#]
       ~@forms)))