PhillyDev Slack #daily_programmer for March 7, 2017

hamming_distance.ex

defmodule HammingDistance do
  @moduledoc """
  Write a program that can calculate the Hamming distance between two DNA
    strands.

  A mutation is simply a mistake that occurs during the creation or copying of a
    nucleic acid, in particular DNA. Because nucleic acids are vital to cellular
    functions, mutations tend to cause a ripple effect throughout the cell.
    Although mutations are technically mistakes, a very rare mutation may equip
    the cell with a beneficial attribute. In fact, the macro effects of
    evolution are attributable by the accumulated result of beneficial
    microscopic mutations over many generations.

  The simplest and most common type of nucleic acid mutation is a point
    mutation, which replaces one base with another at a single nucleotide.

  By counting the number of differences between two homologous DNA strands taken
    from different genomes with a common ancestor, we get a measure of the
    minimum number of point mutations that could have occurred on the
    evolutionary path between the two strands.

  This is called the “Hamming Distance”.
     GAGCCTACTAACGGGAT
     CATCGTAATGACGGCCT
     ^ ^ ^  ^ ^    ^^
  The Hamming distance between these two DNA strands is 7.
  """

  @doc """
  Given two strings - returns the hamming distance

  # Example
      iex> HammingDistance.hammit("GAGCCTACTAACGGGAT", "CATCGTAATGACGGCCT")
      7

      iex> HammingDistance.hammit("GAGCCTACTAACGGGAT", "GAGCCTACTAACGGGAT")
      0
  """
  @spec hammit(String.t, String.t) :: non_neg_integer
  def hammit(left, right) do
    left
    |> String.graphemes
    |> Enum.zip(right |> String.graphemes)
    |> Enum.filter(fn({left, right}) -> left != right end)
    |> Enum.count
  end
end