Instantly share code, notes, and snippets.

@mdaffin /README.md
Last active Jan 24, 2016

Embed
What would you like to do?

C on the teensy 3.1

An example of writing pure c on the teensy 3.1.

Prerequisites

You will need the C compiler, linker and objcopy from the arm-none-eabi toolkit:

  • arm-none-eabi-gcc
  • arm-none-eabi-ld
  • arm-none-eabi-objcopy

You can get them from packge arm-none-eabi-gcc on archlinux or gcc-arm-none-eabi on ubuntu. Otherwise you can get it from CodeSourcery or from your arduino install at $ARDUINO_SDK/hardware/tools/arm/bin.

You will also need the teensy-loader or teensy-loader-cli which you can get here

Linker script: layout.ld

The linker script tells the linker where to place the various bits of code. For more details see this tutorial

C code: blink.c

A minimal example of the C code needed to drive the led on a teensy 3.1. It only initlises parts of the arm chip that are needed to blink the led in order to make it easier to understand. For a more complete example see the the example by karl lunt.

Compile and upload

To compile and upload to the teensy run:

arm-none-eabi-gcc -mcpu=cortex-m4 -mthumb -nostdlib -c -o blink.o blink.c
arm-none-eabi-ld -T layout.ld -o blink.elf blink.o
arm-none-eabi-objcopy -O ihex -R .eeprom blink.elf blink.hex
echo "Reset teensy now"
teensy-loader-cli -w --mcu=mk20dx256 blink.hex

References

  1. Embedded Programming with the GNU Toolchain
  2. Bare-metal Teensy 3.x Development
  3. STM32/ARM Cortex-M3 HOWTO
  4. Teensy3 core code
/*
Copyright (c) 2015 Michael Daffin
Permission is hereby granted, free of charge, to any person obtaining a copy
of this software and associated documentation files (the "Software"), to deal
in the Software without restriction, including without limitation the rights
to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
copies of the Software, and to permit persons to whom the Software is
furnished to do so, subject to the following conditions:
The above copyright notice and this permission notice shall be included in
all copies or substantial portions of the Software.
THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
THE SOFTWARE.
*/
/*
A very basic linker script for the teensy 3.1. Page references refer to the
programmers manual for the MK20DX256VLH7 which can be found at:
https://www.pjrc.com/teensy/K20P64M72SF1RM.pdf
*/
_sflashdata = LOADADDR(.data);
MEMORY {
FLASH (rx) : ORIGIN = 0x00000000, LENGTH = 256K
RAM (rwx) : ORIGIN = 0x1FFF8000, LENGTH = 64K /* page 90 */
}
SECTIONS {
. = 0x00000000;
.text : {
KEEP(*(.vectors)) /* vectors must be placed first - page 63*/
. = 0x400;
KEEP(*(.flashconfig*)) /* flash configuration starts at 0x400 - page 569 */
*(.startup*)
*(.text*)
*(.rodata*)
. = ALIGN(4);
} > FLASH
.data : {
. = ALIGN(4);
_sdata = .;
*(.fastrun*)
*(.data*)
. = ALIGN(4);
_edata = .;
} > RAM AT > FLASH
.bss : {
. = ALIGN(4);
_sbss = .;
*(.bss*)
*(COMMON)
. = ALIGN(4);
_ebss = .;
} > RAM
_estack = ORIGIN(RAM) + LENGTH(RAM); /* stack pointer start */
}
Sign up for free to join this conversation on GitHub. Already have an account? Sign in to comment