Vigra 1.11.0 with vigranumpy for Python 3

PKGBUILD

# $Id: PKGBUILD 257065 2015-12-21 17:09:42Z foutrelis $
# Maintainer: AndyRTR <andyrtr@archlinux.org>
# Contributor: Lukas Jirkovsky <l.jirkovsky@gmail.com>
# Contributor: Martin Drawitsch <mdraw.gh at gmail.com>

pkgbase=vigra
pkgname=('vigra' 'vigra-doc')
pkgver=1.11.0
_pkgver='Version-1-11-0'
pkgrel=1
arch=('x86_64' 'i686')
url="http://hci.iwr.uni-heidelberg.de/vigra/"
license=('custom:MIT')
makedepends=(# runtime deps
             'libpng' 'libtiff' 'openexr' 'gcc-libs' 'sh' 'hdf5' 'fftw'
	         # additional makedeps
             'cmake' 'python-nose' 'doxygen' 'python-sphinx' 'boost' 'python-numpy')
source=("https://github.com/ukoethe/vigra/archive/${_pkgver}.tar.gz")
md5sums=('50b86c85175f9ea8c9d6268d36042b74')

build() {
  cd "${srcdir}"/${pkgbase}-${_pkgver}
  cmake -DCMAKE_INSTALL_PREFIX=/usr \
      -DPYTHON_EXECUTABLE=/usr/bin/python \
      -DWITH_OPENEXR=true \
      -DWITH_VIGRANUMPY=1 \
      -DDOCINSTALL=share/doc
  make
}

check() {
  cd "${srcdir}"/${pkgname}-${_pkgver}
  make -j1 -k check
}

package_vigra() {
  pkgdesc="Computer vision library"
  depends=('libpng' 'libtiff' 'openexr' 'gcc-libs' 'sh' 'hdf5' 'fftw')
  optdepends=('python: for python bindings'
              'boost-libs: for python bindings')

  cd "${srcdir}"/${pkgbase}-${_pkgver}
  make DESTDIR="${pkgdir}" install
  # license
  install -D -m644 LICENSE.txt "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
  
  # remove doc
  rm -rf "${pkgdir}"/usr/share/doc
  
  #fix shebang for python2
  #sed -i 's|python$|python2|' "$pkgdir"/usr/bin/vigra-config
}

package_vigra-doc() {
  pkgdesc="Computer vision library - documentation and examples"
  #depends=('vigra')
  #arch=('any')

  cd "${srcdir}"/${pkgbase}-${_pkgver}
  make DESTDIR="${pkgdir}" install
  # cleanup
  rm -rf "${pkgdir}"/usr/{bin,include,lib}

  # license
  install -D -m644 LICENSE.txt "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
}