figure-grads.gs

'reinit'
'set display color white'
'c'
'sdfopen composite_z500.nc'
'set mproj scaled'
'set mpdraw off'

* 仮想ページを作成、8.5x11in のキャンバスに、この範囲を仮想的にページをする
* 複数の図を掲載する場合は、一つ一つをvpageにして並べる
'set vpage 0.0 7.0 0.0 7.0'
'set grads off'

* dummy variable 
* 正の値と負の値が欲しかったので、てきとうな変数をつくってます
'define v = (var129 - aave(var129,lon=-30,lon=30,lat=-30,lat=30))/1000'

* set axis labels
* EQをなくすために明示的に軸ラベルを定義
'set xlabs | -30 | -25 | -20 | -15 | -10 | -5 | 0 | 5 | 10 | 15 | 20 | 25 | 30 | '
'set ylabs | -30 | -25 | -20 | -15 | -10 | -5 | 0 | 5 | 10 | 15 | 20 | 25 | 30 | '
* 軸の文字を太くし、文字の大きさを変更
'set xlopts 1 9 0.1'
'set ylopts 1 9 0.1'

* set color scheme
'set gxout shaded'
* 青の色が8個入ったら白を入れてる
'color -4 4 0.5 -kind blue-(8)->white-(8)->red'

* draw variable
* 図の描画範囲を決めてる。これがないと、xcbarが右で切れたりする
'set parea 1.0 6.5 1.0 6.5'
'd v'
* x/yのいち、太さなどを指定してカラーバーを描いている
'run xcbar 6.8 7.0 1.7 6.3 -fwidth 0.13 -fheight 0.13 -edge triangle -line on -lc 0'
'set parea off'

* draw text
* 図を描き終わったのでvpageを終了（あとでもいいかも）
'set vpage off'

* draw top left text 左上のテキスト
'set string 1 bl 5 0'
'set strsiz 0.18'
'draw string 0.8 5.45 Z500 hPa'

* draw top right text 右上のテキスト
'set string 1 br 5 0'
'set strsiz 0.18'
'draw string 5.4 5.45 [DJF]'

* draw unit text 単位
'set string 1 l 5 0'
'set strsiz 0.09'
'draw string 5.5 1.2 Unit:'
'draw string 5.5 1.0 m/s'

* draw axis text
* 'draw xlab East-West Axis'    <-- これでもいいけど、フォントが大きいので明示的に書く
* 'draw ylab North-South Axis'
'set string 1 c 5 90'
'set strsiz 0.12'
'draw string 0.3 3.2 North-South Axis'
'set string 1 c 5 0'
'draw string 3.2 0.5 East-West Axis'

* save to file in png ファイルにセーブ。macOSでは設定しないと動かないかも
* works on Rocky. Need to set up Cairo depending on install.

* png output
* - size default is x800 y618 for landscape. Scale from that value.
* サイズは 800x618 の倍数として指定するのがいいみたい
'gxprint fig.png x2400 y1854'

* pdf output
*'gxprint fig.pdf '