A small batch script to convert video to web formats with ffmpeg (supports dropping)

convert.bat

@echo off
SETLOCAL ENABLEDELAYEDEXPANSION
echo video convert to web
echo **************************
echo.

if not "%1"=="" set input=%1
if "%1"=="" set /p input= Input File :

set /p output= Output filename :
if "%output%"=="" (
    for /f "tokens=* delims= " %%f in ('echo %input%') do (
        set output=%%~nf
    )
)

set /p vbitrate= Output video bitrate (8M) :
if "%vbitrate%"=="" set vbitrate=8M

set /p abitrate= Output audio bitrate (128K) :
if "%abitrate%"=="" set abitrate=128K

echo converting to mp4
ffmpeg -i "%input%" -strict -2 -c:a aac -b:a %abitrate% -c:v libx264 -b:v %vbitrate% -crf 20 -maxrate %vbitrate% -bufsize %vbitrate% -movflags +faststart -profile:v high -level 4.2 "%output%.mp4"

echo converting to ogg
ffmpeg -i "%input%" -c:a libvorbis -b:a %abitrate% -c:v libtheora -b:v %vbitrate% "%output%.ogg"

echo converting to webm
ffmpeg -i "%input%" -c:a libvorbis -b:a %abitrate% -c:v libvpx -b:v %vbitrate% -maxrate %vbitrate% -bufsize %vbitrate% -qmin 8 -qmax 42 "%output%.webm"