example

CMakeLists.txt

cmake_minimum_required(VERSION 3.15)

project(example CXX)

find_program(CMAKE_MC_COMPILER mc.exe DOC "WinSDK message compiler")
if(NOT CMAKE_MC_COMPILER)
    message(FATAL_ERROR "mc.exe was not found")
else()
    message(STATUS "mc.exe found at: ${CMAKE_MC_COMPILER}")
endif()

add_custom_command(
    OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/example.rc ${CMAKE_CURRENT_BINARY_DIR}/example.hpp ${CMAKE_CURRENT_BINARY_DIR}/example_MSG00001.bin
    COMMAND ${CMAKE_MC_COMPILER} -b -e hpp -h ${CMAKE_CURRENT_BINARY_DIR} -r ${CMAKE_CURRENT_BINARY_DIR} ${CMAKE_CURRENT_SOURCE_DIR}/example.mc
    DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/example.mc
)

# create a resource-only DLL
add_library(example MODULE ${CMAKE_CURRENT_BINARY_DIR}/example.rc)
set_target_properties(example PROPERTIES LINKER_LANGUAGE CXX)
target_link_options(example PRIVATE $<$<CXX_COMPILER_ID:MSVC>:/noentry>)

example.mc

SeverityNames=(
    Success=0x0:STATUS_SEVERITY_SUCCESS
    Informational=0x1:STATUS_SEVERITY_INFORMATIONAL
    Warning=0x2:STATUS_SEVERITY_WARNING
    Error=0x3:STATUS_SEVERITY_ERROR
)

FacilityNames=(
    System=0x0:FACILITY_SYSTEM
    Example=0x1:FACILITY_EXAMPLE
)

MessageIdTypedef=DWORD

MessageId=0x100
Severity=Error
Facility=Example
SymbolicName=MSG_EXAMPLE_ERROR
Language=English
Example error occurred.
.