Build Qt 5.5.1 from source with MSVC 2015 on Windows

build-x64.bat

REM http://pempek.net/articles/2015/10/18/compiling-qt-5-5-1-with-visual-studio-2015/
REM Set up \Microsoft Visual Studio 2015
CALL "C:\Program Files (x86)\Microsoft Visual Studio 14.0\VC\vcvarsall.bat" amd64
ECHO ON

SET _CD=%CD%
SET _PATH=%PATH%

SET ICU_SOURCE=%_CD%\tools\icu-54.1\source
SET ICU_DIST=%_CD%\tools\icu-54.1\dist-64
SET QT_SOURCE=%_CD%\5.5.1
SET QT_BUILD=%_CD%\msvc2015_64
SET QT_DIST=C:\Programs\Qt\5.5.1\msvc2015_64

REM Building ICU

RD /s /q %ICU_SOURCE%\lib
RD /s /q %ICU_SOURCE%\bin
RD /s /q %ICU_DIST%

CD /D %ICU_SOURCE%
dos2unix *
dos2unix -f configure
for /F %%P in ('cygpath -u %ICU_DIST%') do bash runConfigureICU Cygwin/MSVC -prefix=%%P

make clean
make && make install

CD /D %_CD%
SET PATH=%_PATH%

SET PATH=%PATH%;%ICU_DIST%\bin;%ICU_DIST%\lib
SET INCLUDE=%INCLUDE%;%ICU_DIST%\include
SET LIB=%LIB%;%ICU_DIST%\lib

REM Building Qt

SET PATH=C:\Programs\Qt\tools\Perl64\bin;%PATH%
CALL C:\Programs\Qt\tools\Ruby22-x64\bin\setrbvars.bat
ECHO ON

SET PATH=%QT_SOURCE%\qtbase\bin;%QT_SOURCE%\gnuwin32\bin;%PATH%
REM Uncomment the below line when using a git checkout of the source repository
REM SET PATH=%QT_SOURCE%\qtrepotools\bin;%PATH%
SET QMAKESPEC=win32-msvc2015

RD /s /q %QT_BUILD%
MKDIR %QT_BUILD%
CD /D %QT_BUILD%

CALL %QT_SOURCE%\configure -confirm-license -prefix %QT_DIST% -mp -debug-and-release -icu -nomake examples -nomake tests -skip qtwebkit-examples -opensource
ECHO ON

nmake && nmake install

CD /D %_CD%

COPY /V /Y %ICU_DIST%\lib\icudt54.dll %QT_DIST%\bin\
COPY /V /Y %ICU_DIST%\lib\icuin54.dll %QT_DIST%\bin\
COPY /V /Y %ICU_DIST%\lib\icuuc54.dll %QT_DIST%\bin\

build-x86.bat

REM http://pempek.net/articles/2015/10/18/compiling-qt-5-5-1-with-visual-studio-2015/
REM Set up \Microsoft Visual Studio 2015
CALL "C:\Program Files (x86)\Microsoft Visual Studio 14.0\VC\vcvarsall.bat" x86
ECHO ON

SET _CD=%CD%
SET _PATH=%PATH%

SET ICU_SOURCE=%_CD%\tools\icu-54.1\source
SET ICU_DIST=%_CD%\tools\icu-54.1\dist-32
SET QT_SOURCE=%_CD%\5.5.1
SET QT_BUILD=%_CD%\msvc2015_32
SET QT_DIST=C:\Programs\Qt\5.5.1\msvc2015_32

REM Building ICU

RD /s /q %ICU_SOURCE%\lib
RD /s /q %ICU_SOURCE%\bin
RD /s /q %ICU_DIST%

CD /D %ICU_SOURCE%
dos2unix *
dos2unix -f configure
for /F %%P in ('cygpath -u %ICU_DIST%') do bash runConfigureICU Cygwin/MSVC -prefix=%%P

make clean
make && make install

CD /D %_CD%
SET PATH=%_PATH%

SET PATH=%PATH%;%ICU_DIST%\bin;%ICU_DIST%\lib
SET INCLUDE=%INCLUDE%;%ICU_DIST%\include
SET LIB=%LIB%;%ICU_DIST%\lib

REM Building Qt

SET PATH=C:\Programs\Qt\tools\Perl64\bin;%PATH%
CALL C:\Programs\Qt\tools\Ruby22-x64\bin\setrbvars.bat
ECHO ON

SET PATH=%QT_SOURCE%\qtbase\bin;%QT_SOURCE%\gnuwin32\bin;%PATH%
REM Uncomment the below line when using a git checkout of the source repository
REM SET PATH=%QT_SOURCE%\qtrepotools\bin;%PATH%
SET QMAKESPEC=win32-msvc2015

RD /s /q %QT_BUILD%
MKDIR %QT_BUILD%
CD /D %QT_BUILD%

CALL %QT_SOURCE%\configure -confirm-license -prefix %QT_DIST% -mp -debug-and-release -icu -nomake examples -nomake tests -skip qtwebkit-examples -opensource
ECHO ON

nmake && nmake install

CD /D %_CD%

COPY /V /Y %ICU_DIST%\lib\icudt54.dll %QT_DIST%\bin\
COPY /V /Y %ICU_DIST%\lib\icuin54.dll %QT_DIST%\bin\
COPY /V /Y %ICU_DIST%\lib\icuuc54.dll %QT_DIST%\bin\