markdown dump of all posts on a tag on a particular blog, with other tags saved too

scrape-tag.pl

#!/usr/bin/env perl

use 5.010;
use warnings;
use strict;
use utf8::all;

use HTML::FormatMarkdown;
use Mojolicious 8.02;

sub u { Mojo::URL->new($_[0]) }

my $blog      = "some-blog";
my $tag       = "a tag";
my $separator = '=' x 60;

my $url = u("http://${blog}.tumblr.com/tagged/" . $tag =~ y/ /-/r);

my $ua = Mojo::UserAgent->new;

while ($url) {
  my $dom = $ua->get($url)->result->dom;

  $dom->find('article.post')->each(sub {
    say $separator;
    say get_tags($_) . "\n";
    say HTML::FormatMarkdown->format_string(
      $_->at('div.post-content')->content,
      rightmargin => 9999999,
    ) . "\n\n";
  });

  if (my $next = $dom->at('a#next')) {
    $url = u($next->attr('href'))->base($url)->to_abs;
  }
  else {
    undef $url;
  }
  exit;
}

sub get_tags {
  my ($dom) = @_;

  $dom->find('a.tag')
    ->map('content')
    ->map(\&Mojo::Util::html_unescape)
    ->grep(sub { $_ ne $tag })
    ->join(', ');
}