PKGBUILD

# Maintainer: Gavin Lloyd <gavinhungry@gmail.com>

pkgname=acme.sh-git
pkgver=0.1872.3e10152
pkgrel=1
pkgdesc='An ACME Shell script, an acme client alternative to certbot'
arch=('any')
url='https://github.com/Neilpang/acme.sh'
license=('GPL3')
makedepends=('git')
source=("${pkgname}::git+${url}.git#branch=master")
sha256sums=('SKIP')

pkgver() {
  cd "${srcdir}/${pkgname}"
  echo 0.$(git rev-list --count HEAD).$(git rev-parse --short HEAD)
}

package() {
  cd "${srcdir}/${pkgname}"

  install -dm755 "${pkgdir}/usr/share/acme.sh"
  cp -r acme.sh deploy dnsapi "${pkgdir}/usr/share/acme.sh"

  install -dm755 "${pkgdir}/usr/bin"
  ln -s /usr/share/acme.sh/acme.sh "${pkgdir}/usr/bin/acme.sh"
}

PKGBUILD.diff

diff --git a/PKGBUILD b/PKGBUILD
index 4f5f1f2..e933667 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,8 +1,8 @@
 # Maintainer: Gavin Lloyd <gavinhungry@gmail.com>
 
 pkgname=acme.sh-git
-pkgver=0.1734.8aff2bd
-pkgrel=6
+pkgver=0.1872.3e10152
+pkgrel=1
 pkgdesc='An ACME Shell script, an acme client alternative to certbot'
 arch=('any')
 url='https://github.com/Neilpang/acme.sh'
@@ -17,5 +17,11 @@ pkgver() {
 }
 
 package() {
-  install -Dm755 "${srcdir}/${pkgname}"/acme.sh "${pkgdir}"/usr/bin/acme.sh
+  cd "${srcdir}/${pkgname}"
+
+  install -dm755 "${pkgdir}/usr/share/acme.sh"
+  cp -r acme.sh deploy dnsapi "${pkgdir}/usr/share/acme.sh"
+
+  install -dm755 "${pkgdir}/usr/bin"
+  ln -s /usr/share/acme.sh/acme.sh "${pkgdir}/usr/bin/acme.sh"
 }