PKGBUILD

# Maintainer: d.woffinden
pkgname=z3-git
pkgver=4.4.1.r1411.g218e47f
pkgrel=1
pkgdesc="Z3 is a high-performance theorem prover being developed at Microsoft Research"
arch=('i686' 'x86_64')
url="https://github.com/Z3Prover/z3"
license=('MIT')
depends=('gcc-libs')
makedepends=('git' 'python2')
optdepends=('python2: bindings for python2')
conflicts=('z3-bin' 'z3-codeplex')
provides=('z3')
# The git repo is detected by the 'git:' or 'git+' beginning. The branch
# '$pkgname' is then checked out upon cloning, expediating versioning:
source=("$pkgname"::"git+$url")
# Because the sources are not static, skip Git checksum:
md5sums=('SKIP')

pkgver() {
  cd "$pkgname"
  git describe --long | sed 's/z3-//;s/-/.r/;s/-/./'
}

build() {
  cd "$srcdir/$pkgname"
  LANG=C python2 scripts/mk_make.py --python

  cd "$srcdir/$pkgname/build"
  make
}

package() {
  cd "$srcdir/$pkgname/build"
  make install DESTDIR="$pkgdir"

  cd "$srcdir/$pkgname"
  install -Dm644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}