Haskell Do Notation for JavaScript Promises

dopromise.coffee

COMPILED_COFFEE = ' < -'
PLAIN_JS = '<-'

thenify = (lines) ->
    [line, rest...] = lines
    if rest.length is 0
        line
    else if line.search(PLAIN_JS) > 0 or line.search(COMPILED_COFFEE) > 0
        [value, promise] = line.split if line.search(PLAIN_JS) > 0 then PLAIN_JS else COMPILED_COFFEE
        noSemiColon = promise.slice(0, -1)
        "return #{noSemiColon}.then(function(#{value}){"+
            thenify(rest) +
        "});"
    else 
        line + '\n' + thenify rest
 
doPromise = (fn) ->
    lines = fn.toString().split '\n'
    withArgs = lines[0]
    body = lines.slice(1, -1).map (x) -> x.trim()
    newFn = thenify(body)
    with: (args...)->
        eval("(#{withArgs}#{newFn}})")(args...)
# EXAMPLE

# doPromise (get, savetoDatabase)->
#   data <- get 'some stuff'
#   ids <- saveToDatabase data
#   {data, ids}
# .with get, savetoDatabase
#
# compiles to:
#
# doPromise(function(get, savetoDatabase) {
#  data < -get('some stuff');
#  ids < -saveToDatabase(data);
#  return {
#    data: data,
#    ids: ids
#  };
# })["with"](get, savetoDatabase);
#
# which gets transformed into this:
#
# function (get, saveToDatabase) {
#    return get('some stuff').then(function (data) {
#        return saveToDatabase(data).then(function (ids) {
#            return {
#                data: data,
#                ids: ids
#            };
#        });
#    })["with"](get, savetoDatabase);
#
# yay monads!