My .vimrc configuration for working in Python with vim

.vimrc

" plugins
let need_to_install_plugins = 0
if empty(glob('~/.vim/autoload/plug.vim'))
    silent !curl -fLo ~/.vim/autoload/plug.vim --create-dirs
        \ https://raw.githubusercontent.com/junegunn/vim-plug/master/plug.vim
    let need_to_install_plugins = 1
endif

call plug#begin()
Plug 'tpope/vim-sensible'
Plug 'itchyny/lightline.vim'
Plug 'joshdick/onedark.vim'
Plug 'ap/vim-buftabline'
Plug 'airblade/vim-gitgutter'
Plug 'preservim/nerdtree'
Plug 'jistr/vim-nerdtree-tabs'
Plug 'Xuyuanp/nerdtree-git-plugin'
Plug 'jiangmiao/auto-pairs'
Plug 'dense-analysis/ale'
Plug 'majutsushi/tagbar'
Plug 'vim-scripts/indentpython.vim'
Plug 'lepture/vim-jinja'
Plug 'pangloss/vim-javascript'
Plug 'alvan/vim-closetag'
Plug 'maxmellon/vim-jsx-pretty'
call plug#end()

filetype plugin indent on
syntax on

if need_to_install_plugins == 1
    echo "Installing plugins..."
    silent! PlugInstall
    echo "Done!"
    q
endif

" always show the status bar
set laststatus=2

" enable 256 colors
set t_Co=256
set t_ut=

" turn on line numbering
set number

" sane text files
set fileformat=unix
set encoding=utf-8
set fileencoding=utf-8

" sane editing
set tabstop=4
set shiftwidth=4
set softtabstop=4
set colorcolumn=80
set expandtab
set viminfo='25,\"50,n~/.viminfo
autocmd FileType html setlocal tabstop=2 shiftwidth=2 softtabstop=2
autocmd FileType css setlocal tabstop=2 shiftwidth=2 softtabstop=2
autocmd FileType javascript setlocal tabstop=2 shiftwidth=2 softtabstop=2

" auto-pairs
au FileType python let b:AutoPairs = AutoPairsDefine({"f'" : "'", "r'" : "'", "b'" : "'"})

" word movement
imap <S-Left> <Esc>bi
nmap <S-Left> b
imap <S-Right> <Esc><Right>wi
nmap <S-Right> w

" indent/unindent with tab/shift-tab
nmap <Tab> >>
nmap <S-tab> <<
imap <S-Tab> <Esc><<i
vmap <Tab> >gv
vmap <S-Tab> <gv

" mouse
set mouse=a
let g:is_mouse_enabled = 1
noremap <silent> <Leader>m :call ToggleMouse()<CR>
function ToggleMouse()
    if g:is_mouse_enabled == 1
        echo "Mouse OFF"
        set mouse=
        let g:is_mouse_enabled = 0
    else
        echo "Mouse ON"
        set mouse=a
        let g:is_mouse_enabled = 1
    endif
endfunction

" color scheme
syntax on
colorscheme onedark
filetype on
filetype plugin indent on

" lightline
set noshowmode
let g:lightline = { 'colorscheme': 'onedark' }

" code folding
set foldmethod=indent
set foldlevel=99

" wrap toggle
setlocal nowrap
noremap <silent> <Leader>w :call ToggleWrap()<CR>
function ToggleWrap()
    if &wrap
        echo "Wrap OFF"
        setlocal nowrap
        set virtualedit=all
        silent! nunmap <buffer> <Up>
        silent! nunmap <buffer> <Down>
        silent! nunmap <buffer> <Home>
        silent! nunmap <buffer> <End>
        silent! iunmap <buffer> <Up>
        silent! iunmap <buffer> <Down>
        silent! iunmap <buffer> <Home>
        silent! iunmap <buffer> <End>
    else
        echo "Wrap ON"
        setlocal wrap linebreak nolist
        set virtualedit=
        setlocal display+=lastline
        noremap  <buffer> <silent> <Up>   gk
        noremap  <buffer> <silent> <Down> gj
        noremap  <buffer> <silent> <Home> g<Home>
        noremap  <buffer> <silent> <End>  g<End>
        inoremap <buffer> <silent> <Up>   <C-o>gk
        inoremap <buffer> <silent> <Down> <C-o>gj
        inoremap <buffer> <silent> <Home> <C-o>g<Home>
        inoremap <buffer> <silent> <End>  <C-o>g<End>
    endif
endfunction

" move through split windows
nmap <leader><Up> :wincmd k<CR>
nmap <leader><Down> :wincmd j<CR>
nmap <leader><Left> :wincmd h<CR>
nmap <leader><Right> :wincmd l<CR>

" move through buffers
nmap <leader>[ :bp!<CR>
nmap <leader>] :bn!<CR>
nmap <leader>x :bd<CR>

" restore place in file from previous session
autocmd BufReadPost * if line("'\"") > 1 && line("'\"") <= line("$") | exe "normal! g'\"" | endif

" file browser
let NERDTreeIgnore = ['\.pyc$', '__pycache__']
let NERDTreeMinimalUI = 1
let g:nerdtree_open = 0
map <leader>n :call NERDTreeToggle()<CR>
function NERDTreeToggle()
    NERDTreeTabsToggle
    if g:nerdtree_open == 1
        let g:nerdtree_open = 0
    else
        let g:nerdtree_open = 1
        wincmd p
    endif
endfunction

function! StartUp()
    if 0 == argc()
        NERDTree
    end
endfunction
autocmd VimEnter * call StartUp()

" ale
map <C-e> <Plug>(ale_next_wrap)
map <C-r> <Plug>(ale_previous_wrap)

" tags
map <leader>t :TagbarToggle<CR>

" copy, cut and paste
vmap <C-c> "+y
vmap <C-x> "+c
vmap <C-v> c<ESC>"+p
imap <C-v> <ESC>"+pa

" disable autoindent when pasting text
" source: https://coderwall.com/p/if9mda/automatically-set-paste-mode-in-vim-when-pasting-in-insert-mode
let &t_SI .= "\<Esc>[?2004h"
let &t_EI .= "\<Esc>[?2004l"

function! XTermPasteBegin()
    set pastetoggle=<Esc>[201~
    set paste
    return ""
endfunction

inoremap <special> <expr> <Esc>[200~ XTermPasteBegin()

Hi
I get this issue on Linux
I added .vimrc in my home
I launched vim or vi , i get this below

Error detected while processing /u/users/ray1234/.vimrc:
line 2:
E15: Invalid expression: 0^M
line 3:
E15: Invalid expression: empty(glob('~/.vim/autoload/plug.vim'))^M
line 184:
E171: Missing :endif
Press ENTER or type command to continue

What version of vim do you have?

What version of vim do you have?

VIM - Vi IMproved 7.4
I got it working. Problem was copy paste from windows to linux,
I did a curl and got it working.
The FileManager on left and center workspace works with \n & \t.
but the methods/functions on right does not work , some ctags issue i guess.
But its great for my python work in linux.
I am vim fan.

Do yourself a favor and upgrade to 8.1 - nothing to loose there while you'll have many benefits. Check it out here

REgarding your problem, it might be related to end of line characters.

It seems that my vim can't copy to the system clipboard (I'm in Linux Fedora 31). I have to disable the mouse (and the lateral sections) to use the terminal ctrl+shift+c (quite ugly in comparison to, say, the powerful notepad++ on windows or even the basic write editor - gedit - in my Linux) or do you know a better trick? Indeed, for this reason, I'm using gedit and not vim on Linux when I want to copy some code from a python file to the browser (in a gist like this, for example). Thank you anyway for this awesome configuration!

If my Ctrl-C/Ctrl-X/Ctrl-V key definitions do not work it is probably because your vim wasn't built with system clipboard support. See https://vim.fandom.com/wiki/Accessing_the_system_clipboard for info on how to check if your vim was built with clipboard support or not.

Now separate from that, if you like your terminal window's mouse based text selection and clipboard usage, you can typically get those to work even while mouse is enabled in vim. On my Mac, for example, I can bypass vim's mouse support and access the iTerm2 text selection by pressing the Option key when selecting text with the mouse. Try selecting text while pressing Alt, Shift, etc. to see if you find a key that works on your Linux machine.

Oh yes, I could press Shift while selecting with the mouse, you're right (indeed I've also found the same tip here), but in that case I'd better close the left navigator and it's still ugly to see the line numbers.
Well, I've followed this so installed vim-X11 plus started vimx instead of vim and now the + buffer is copying to the clipboard (not the * buffer). So problem solved, somehow.
But I still can't see your Ctrl-C work, even if I've checked that, now, if I select with the mouse and I type "+y it works (so it's strange that your config shortcut is lost). Notice that if, in normal mode, I open the command : and I enter vmap <C-c> "+y, it gets enabled, so I guess it is overwritten at startup, don't know why (o which plugin).
In conclusion, thank you for your competent reply, for this wonderful config and for your valuable and instructive videos, kind regards.

Hello @miguelgrinberg,

Coming from your youtube video, I'm using vim plug as well, and saw you're using tmux, what kind of customisations did you to have both of them working together (the mouse wheel, or the color support for instance) <

Best.

@bmillemathias-1a I didn't really go too crazy on the tmux + vim config. On the tmux side I have mouse enabled, which makes scrolling with the wheel work nicely. 256 color support is also enabled with xterm-256color. A video on tmux is coming soon, by the way.

Hi,
I am trying to source this .vimrc in my WSL ubuntu and I am getting the following errors. Any suggestions on how to resolve these errors ?

-bash: source: filename argument required
source: usage: source filename [arguments]
-bash: plugins
let need_to_install_plugins = 0
if empty(glob('~/.vim/autoload/plug.vim'))
silent !curl -fLo ~/.vim/autoload/plug.vim --create-dirs
\ https://raw.githubusercontent.com/junegunn/vim-plug/master/plug.vim
autocmd: No such file or directory
-bash: let: =: syntax error: operand expected (error token is "=")
endif: command not found
-bash: /home/dkadiyala3/.vimrc: line 13: syntax error near unexpected token (' -bash: /home/dkadiyala3/.vimrc: line 13: call plug#begin()'

This file is not for sourcing, you just have to put it in your home directory.

@miguelgrinberg Thank you very much!!

Thank you Miguel for the video and sharing your config file.

I have a question regarding commenting multiple lines of code in vim. I normally just do ctrl + / in VS Code but in vim, some of the solutions I've found take too many keystrokes. There's also several plugins but now I'm just offered too many choices.

What is your process for quickly commenting out multiple lines of code?

@mchlsm I don't have a shortcut built for this. You have to put the cursor on the place where you want the # to be in the first line. Select Ctrl-V for visual block mode, then down arrow until the bottom line. Then Shift-I to insert before cursor, then type the # and maybe a space after it, and finally ESC.

To uncomment use Ctrl-V down arrow to the bottom line, right arrow if you added a space after the #. Then x to remove the comments.

@mchlsm I don't have a shortcut built for this. You have to put the cursor on the place where you want the # to be in the first line. Select Ctrl-V for visual block mode, then down arrow until the bottom line. Then Shift-I to insert before cursor, then type the # and maybe a space after it, and finally ESC.

To uncomment use Ctrl-V down arrow to the bottom line, right arrow if you added a space after the #. Then x to remove the comments.

It's a little strange that you don't see the comment marker appear on every line immediately after you do Shift-I and start typing (you only see it on the main line you initially selected). The rest of the comment marks only appear after you press ESC. For me, I had to press ESC twice. I suppose I will just have to do this more to make it a muscle memory.

Uncommenting worked great.

Thank you!

I was getting an annoying error for gtk c files with gtk.h include, and found this suggestion useful:

let g:syntastic_c_config_file = '.config_c'
let g:syntastic_c_no_include_search = 1

Now it works as expected (notice that also a config_c is needed however)

How can I add autocomplete. I have tried editing the pluggins but it shows error everytime. Can you help me there. Thanks in advance

I don't use autocomplete plugins because I haven't found one that works well. You may need to raise an issue on the plugin's repo, or ask in StackOverflow. Sorry.

Hi @miguelgrinberg, Thanks for this vimrc file.
I have one question like when I open multiple files. I see the tabs at the top. So how to switch between the tabs to switch from one file to another?

To switch tabs I have configured the [ and ] key sequences (backslash and one of the square brackets).

Perfect! Thank You So Much @miguelgrinberg

Hi @miguelgrinberg, really thank you for sharing your vim configuration file.

The file browser doesn't work on my vim, when I try to open it with \n, following errors occur, any idea how I could solve this?

rror detected while processing function NERDTreeToggle[1]..<SNR>45_NERDTreeToggleAllTabs[7]..<SNR>45_NERDTreeOpenAllTabs[5]..<SNR>45_NERDTreeMirrorOrCreat
e[12]..194[2]..195[12]..180[26]..183[7]..146[9]..144[32]..240[4]..NERDTreeGitStatusRefreshListener[5]..NERDTreeGetGitStatusPrefix:                         
line    6:                                                                                                                                                 
E117: Unknown function: nerdtree#slash                                                                                                                     
Error detected while processing function NERDTreeToggle[1]..<SNR>45_NERDTreeToggleAllTabs[7]..<SNR>45_NERDTreeOpenAllTabs[5]..<SNR>45_NERDTreeMirrorOrCreat
e[12]..194[2]..195[12]..180[26]..183[7]..146:                                                                                                              
line    9:                                                                                                                                                 
E171: Missing :endif                                                                                                                                       
Error detected while processing function NERDTreeToggle[1]..<SNR>45_NERDTreeToggleAllTabs[7]..<SNR>45_NERDTreeOpenAllTabs[5]..<SNR>45_NERDTreeMirrorOrCreat
e[12]..194[2]..195:                                                                                                                                        
line   12:                                                                                                                                                 
E171: Missing :endif                                                                                                                                       
Error detected while processing function NERDTreeToggle[1]..<SNR>45_NERDTreeToggleAllTabs[7]..<SNR>45_NERDTreeOpenAllTabs[5]..<SNR>45_NERDTreeMirrorOrCreat
e:                                                                                                                                                         
line   12:                                                                                                                                                 
E171: Missing :endif                                                                                                                                       
Error detected while processing function NERDTreeToggle[1]..<SNR>45_NERDTreeToggleAllTabs:                                                                 
line    7:                                                                                                                                                 
E171: Missing :endif                                                                                                                                       

@RichardBaker3020 I'm not sure. Make sure your vim is a version 8.x, and also that you don't have any leftovers from a previous installation, by deleting or renaming the .vim directory.

@miguelgrinberg, thanks for sharing this. Are you not currently using code completion? Do you suggest that we use code completion while using vim for python? I enjoyed VSCode for this reason. Also, I was able to find https://github.com/ycm-core/YouCompleteMe which I may add to my vimrc file.

@evanniedojadlo That's correct, I do not use code completion with vim. There are several plugins that can do it, and they fall into two categories: there are those that aren't too good, and those that are good but are painful to install. I use vim as a quick editor that is available everywhere, if I wanted a full blown IDE with code completion there are better choices. That said, there is no reason why you shouldn't experiment and see if you find a vim completion solution that you like.

@miguelgrinberg excellent, thank you! I appreciate that realistic perspective.

Hi,
thanks for contributing with .vimrc, it worked for me in vim 8.2, now I think I have a basic question where can I find the shorcuts like backslash n (\n). I am really new in VIM.

Thanks in advance,

Xavier

@xavysp the "backslash n" shortcut is done by pressing the backslash key (i.e. \), releasing it, and then pressing the letter n. The backslash is called the "leader" key, it is used as a prefix for a lot of commands, a few of which I have defined in this config file.

Do you have a list or notes on most useful/common shortcuts and options for this vimrc?

@nadiiach There are very few shortcuts added in this config file, actually. You can find them by searching for the lines that use the key mapping commands such as map, imap, etc.

Did you modify some settings for Tagbar? I would like a cleaner tagbar like the one I saw in your video but I get something like
__init__(self, **kwargs) : member and generate_confirmation_token(self, expiration=3600) : member
which take up too much space and don't look very good.

Thanks for sharing this configuration. Really helpful.

@hakanohi I haven't changed anything, but clearly you have long symbols in your source code. See here for how to resize the pane.

Error detected while processing function NERDTreeToggle[1]..<SNR>45_NERDTreeToggleAllTabs[7]..<SNR>45_NERDTreeOpenAllTabs[5]..<SNR>45_NERDTreeMirrorOrCreate[12]..194[2]..195[12]..180[26]..183[7]..146[9]..144[32]..240:
line    3:                                                                                       E704: Funcref variable name must start with a capital: listener                                  Error detected while processing function NERDTreeToggle[1]..<SNR>45_NERDTreeToggleAllTabs[7]..<SNR>45_NERDTreeOpenAllTabs[5]..<SNR>45_NERDTreeMirrorOrCreate[12]..194[2]..195[12]..180[26]..183[7]..146:                                                                                           
line    9:                                                                                       E171: Missing :endif                                                                             Error detected while processing function NERDTreeToggle[1]..<SNR>45_NERDTreeToggleAllTabs[7]..<SNR>45_NERDTreeOpenAllTabs[5]..<SNR>45_NERDTreeMirrorOrCreate[12]..194[2]..195:                    
line   12:                                                                                       E171: Missing :endif                                                                             Error detected while processing function NERDTreeToggle[1]..<SNR>45_NERDTreeToggleAllTabs[7]..<SNR>45_NERDTreeOpenAllTabs[5]..<SNR>45_NERDTreeMirrorOrCreate:                                     
line   12:                                                                                       E171: Missing :endif                                                                             Error detected while processing function NERDTreeToggle[1]..<SNR>45_NERDTreeToggleAllTabs:       line    7:                                                                                       E171: Missing :endif    

@rs9899 My only guess is that you are not using a recent vim version, but that's just that a guess. I suggest you ask in StackOverflow or in the NERDTree project.

Error detected while processing function NERDTreeToggle[1]..45_NERDTreeToggleAllTabs[7]..45_NERDTreeOpenAllTabs[5]..45_NERDTreeMirrorOr
Create[12]..194[2]..195[12]..180[26]..183[7]..146[9]..144[32]..240:
line 3:
E704: Funcref variable name must start with a capital: listener
Error detected while processing function NERDTreeToggle[1]..45_NERDTreeToggleAllTabs[7]..45_NERDTreeOpenAllTabs[5]..45_NERDTreeMirrorOr
Create[12]..194[2]..195[12]..180[26]..183[7]..146:
line 9:
E171: Missing :endif
Error detected while processing function NERDTreeToggle[1]..45_NERDTreeToggleAllTabs[7]..45_NERDTreeOpenAllTabs[5]..45_NERDTreeMirrorOr
Create[12]..194[2]..195:
line 12:
E171: Missing :endif
Error detected while processing function NERDTreeToggle[1]..45_NERDTreeToggleAllTabs[7]..45_NERDTreeOpenAllTabs[5]..45_NERDTreeMirrorOr
Create:
line 12:
E171: Missing :endif
Error detected while processing function NERDTreeToggle[1]..45_NERDTreeToggleAllTabs:
line 7:
E171: Missing :endif

vim version is 8.1
and yes i deleted old file and then downloaded vimrc file

@vaibhavkumar049 as I said above, I'm not the right person to ask about this. Your vim instance is incompatible with this extensions, but I really don't know why. Vim can be compiled with many options enabled or disabled, you are missing something. Go find someone who knows more about this, I really don't know.

@vaibhavkumar049

i added this and it seems to solve my problem...
call plug#begin()
Plug 'preservim/nerdtree'
call plug#end()

let me know if it helps:)

@Binit-Dhakal This works for me, there's still an error message though, but I guess that doesn't matter as file explorer could open normally, Thanks :)

@Binit-Dhakal, thankyou so much this plugin of nerdtree works for me too

@RichardBaker3020 I think the error is because of another plugin of nerdtree, if you remove that, it would be fine

@Binit-Dhakal thanks, I wasn't aware there was a newer fork of nerdtree. I have tested it and it appears to work fine for me so I have updated this gist to use it. Thanks!

@RichardBaker3020
I was having the same issue. Turned out the function! StartUp() block was missing from my vimrc for some reason. I also replaced the 'preservim/nerdtree' with 'scrooloose/nerdtree' and now it works without any warnings.