build.gradle.kts

// Workaround for IDEA-265203
System.setProperty("user.dir", projectDir.toString())

plugins {
    // Support convention plugins written in Kotlin. Convention plugins are build scripts in 'src/main' that automatically become available as plugins in the main build.
    `kotlin-dsl`
}

repositories {
    // Use the plugin portal to apply community plugins in convention plugins.
    gradlePluginPortal()
    maven {
        url = uri("https://maven.hq.hydraulic.software")
    }
    val localRepo = rootProject.projectDir.resolve("../build/repo")
    if (localRepo.exists()) {
        maven {
            url = uri(localRepo)
        }
    }
}

val kotlinVersion = "1.6.10"

dependencies {
    // Kotlin
    implementation("org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlinVersion")
    implementation("org.jetbrains.kotlin:kotlin-reflect:$kotlinVersion")
    // Documentation website generation.
    implementation("org.jetbrains.dokka:dokka-gradle-plugin:1.6.20")
    // Make assert(), require(), check() etc print useful diagrams with values when they fail.
    implementation("gradle.plugin.com.bnorm.power:kotlin-power-assert-gradle:0.11.0")
    // Fat JARs.
    implementation("gradle.plugin.com.github.jengelman.gradle.plugins:shadow:7.0.0")
    // Prettier unit test run output.
    implementation("com.adarshr:gradle-test-logger-plugin:3.0.0")
    // Checking if dependency versions are up to date.
    implementation("com.github.ben-manes:gradle-versions-plugin:0.39.0")
    // File downloads (not built in for some reason).
    implementation("de.undercouch:gradle-download-task:4.1.2")
    // Arrow Analysis: static analysis (currently unused).
    implementation("io.arrow-kt.analysis.kotlin:io.arrow-kt.analysis.kotlin.gradle.plugin:2.0")
    // Task Tree: visualize how tasks depend on each other.
    implementation("com.dorongold.plugins:task-tree:2.1.0")
}