Norns Engine Development on MacOS - quick guide

!norns_on_mac.md

1. Pull the norns repository

2. Make symbolic links from norns sc folders -> SuperCollider Extensions folder:

   • ln -s ~/Developer/monome/norns/sc/core ~/Library/Application\ Support/SuperCollider/Extensions/monome-norns-core
   • ln -s ~/Developer/monome/norns/sc/engines ~/Library/Application\ Support/SuperCollider/Extensions/monome-norns-engines
   • ln -s ~/Developer/monome/norns/sc/ugens ~/Library/Application\ Support/SuperCollider/Extensions/monome-norns-ugens

3. Make symlinks to Norns community repos e.g. ln -s ~/Developer/monome/we/ ~/Library/Application\ Support/SuperCollider/Extensions/monome-we

4. Make symlinks for custom engine development e.g. ln -s ~/Developer/MyNornsMachines/ ~/Library/Application\ Support/SuperCollider/Extensions/MyNornsMachines

5. If you're running Jack on MacOS, you will want to comment out lines related to Jack connection in Crone.sc

engine_development_example.scd

// thanks to @zebra: https://llllllll.co/t/norns-crone-supercollider/14616/129?u=mimetaur

n = NetAddr.localAddr;

n.sendMsg('/engine/load/name', 'PolyPercPannable');

// equivalently:
// Crone.setEngine('Engine_PolyPercPannable')

n.sendMsg('/command/hz', 330);
n.sendMsg('/command/amp', 0.5);

Engine_PolyPercPannable.sc

// CroneEngine_PolyPercPannable
// sine with perc envelopes triggered on freq
// panning added
// make sure this lives on your SC include paths
// by @mimetaur

Engine_PolyPercPannable : CroneEngine {
	var pg;
    var amp=0.3;
    var release=0.5;
    var pw=0.5;
    var cutoff=1000;
    var gain=2;
	var pan=0;

	*new { arg context, doneCallback;
		^super.new(context, doneCallback);
	}

	alloc {
		pg = ParGroup.tail(context.xg);
        SynthDef("PolyPerc", {
			arg out, freq = 440, pw=pw, amp=amp, cutoff=cutoff, gain=gain, release=release, pan=pan;
			var snd = Pulse.ar(freq, pw);
			var filt = MoogFF.ar(snd,cutoff,gain);
			var env = Env.perc(level: amp, releaseTime: release).kr(2);
			//			out.poll;

			Out.ar(out, Pan2.ar( (filt * env), pan));
		}).add;

		this.addCommand("hz", "f", { arg msg;
			var val = msg[1];
            Synth("PolyPerc", [\out, context.out_b, \freq,val,\pw,pw,\amp,amp,\cutoff,cutoff,\gain,gain,\release,release,\pan,pan], target:pg);
		});

		this.addCommand("amp", "f", { arg msg;
			amp = msg[1];
		});

		this.addCommand("pw", "f", { arg msg;
			pw = msg[1];
		});
		this.addCommand("release", "f", { arg msg;
			release = msg[1];
		});
		this.addCommand("cutoff", "f", { arg msg;
			cutoff = msg[1];
		});
		this.addCommand("gain", "f", { arg msg;
			gain = msg[1];
		});
		this.addCommand("pan", "f", { arg msg;
			pan = msg[1];
		});
	}
}

thanks for doing this
quick feedback:

the .yaml is generated by supercollider, probably not great to edit it directly

currently we set up the language paths here:
https://github.com/monome/norns/blob/dev/sc/norns-config.sc

in a chicken/egg problem, if you do it this way this file needs to be discoverable by SC in the first place (e.g. in Application Support/SuperCollider/Extensions on macos), and actually you need to launch sclang a couple of times for changes there to 'take' (and overwrite the .yaml)

my preferred approach for delveopment is actually to bypass all this weirdness and make symlinks from SC Extensions to the stuff you need:

~norns/sc/core
~dust

BTW: we'll be cleaning up some cruft from norns/sc/engines, norns/sc/ugens. you shouldn't need them for most things.

Noted, I just switched to symlinks locally and it works great, with none of the weirdness I hit from editing norns-config.sc. Updated the gist accordingly.