PKGBUILD for Gazebo 8 in AUR

PKGBUILD

# Maintainer: marauder <abhinav dot kssk at gmail dot com>
# Contributor: Benjamin Chretien <chretien at lirmm dot fr>
# Contributor: Anton Bazhenov <anton.bazhenov at gmail>
# Contributor: Vladimir Ermakov <vooon341@gmail.com>
# Contributor: Yuxiang Li <li.yuxiang.nj at gmail dot com>
# Contributor: Miguel Morales <mimoralea at gmail dot com>

pkgname=gazebo
pkgver=8.0.0
pkgrel=1
pkgdesc="A multi-robot simulator for outdoor environments"
arch=('i686' 'x86_64')
url="http://gazebosim.org/"
license=('Apache')
# See: http://www.gazebosim.org/tutorials?tut=install_from_source&cat=install
depends=('boost>=1.40.0' 'curl>=4.0' 'freeglut' 'freeimage>=3.0' 'gperftools'
         'intel-tbb>=3.0' 'libccd>=1.4' 'libltdl>=2.4.2' 'libtar>=1.2' 'libxml2>=2.7.7'
         'ogre' 'protobuf>=2.3.0' 'sdformat>=5.0.0' 'ignition-math>=3' 'ignition-transport>=3' 'ignition-msgs' 
         'tinyxml' 'tinyxml2' 'qwt-qt5' 'qt5-webkit-ng' 'qt5-base' )
optdepends=('bullet>=2.82: Bullet support'
            'cegui>=0.8.3: Design custom graphical interfaces'
            'ffmpeg: Playback movies on textured surfaces'
            'gdal: Digital elevation terrains support'
            'libdart>=5.1: DART support'
            'libspnav: space navigator joystick support'
            'libusb: USB peripherals support'
            'ruby-ronn: Generate manpages'
            'simbody>=3.3: Simbody support'
            'urdfdom: Load URDF files'
            'openal: Audio support'
            'hdf5' 'graphviz')
makedepends=('cmake' 'doxygen' 'pkg-config>=0.26')
install="${pkgname}.install"
provides=('gazebo')

_dir=osrf-gazebo-85ba68a2545f
source=(https://bitbucket.org/osrf/gazebo/get/gazebo8_8.0.0.tar.bz2)
md5sums=('SKIP')

build() {
  cd "$srcdir/$_dir"

  mkdir -p build
  cd build

  # Configure build
  cmake .. -DCMAKE_BUILD_TYPE="Release" \
           -DCMAKE_INSTALL_PREFIX="/usr" \
           -DCMAKE_INSTALL_LIBDIR="lib" 

  # Compile
  make -j4
}

package() {
  cd "$srcdir/$_dir/build"
  make DESTDIR="$pkgdir/" install
}