quasiquoter for compile-time checks without TH splices

Email.hs

{-# LANGUAGE QuasiQuotes #-}
{-# LANGUAGE TemplateHaskellQuotes #-}
{-# LANGUAGE DeriveLift #-}

module Email where

import Language.Haskell.TH.Quote (QuasiQuoter(..))
import Language.Haskell.TH.Syntax (Lift, lift, Q, Exp)

-- don't expose this constructor
newtype Email = Email String
  deriving (Show, Lift)

-- do expose this smart constructor
mkEmail :: String -> Maybe Email
mkEmail email =
  if isValidEmail email then Just (Email email) else Nothing
  where
    -- you'd want this to check more conditions
    isValidEmail email = '@' `elem` email

email :: QuasiQuoter
email =
  QuasiQuoter
    { quoteExp = \s ->
        case mkEmail s of
          Nothing -> fail $ "`" <> show s <> "` is not a valid email"
          Just email -> lift email
    , quotePat = error "email is not a pattern"
    , quoteDec = error "email is not a declaration"
    , quoteType = error "email is not a type"
    }

-- usage:
--
-- {-# LANGUAGE QuasiQuotes #-} -- you just need QuasiQuotes
-- [email|test@test.com|] -- then use this as a compile-time-checked expression