Generating and using a virtualenv from CMake

CMakeLists.txt

cmake_minimum_required(VERSION 3.6)

project(CmakeVirtualenv)

enable_testing()

# Find Python and Virtualenv. We don't actually use the output of the
# find_package, but it'll give nicer errors.
find_package(PythonInterp 2.7 REQUIRED)
find_program(VIRTUALENV virtualenv)
if(NOT VIRTUALENV)
    message(FATAL_ERROR "Could not find `virtualenv` in PATH")
endif()
set(VIRTUALENV ${VIRTUALENV} -p python2.7)

# Generate the virtualenv and ensure it's up to date.
add_custom_command(
    OUTPUT venv
    COMMAND ${VIRTUALENV} venv
)
add_custom_command(
    OUTPUT venv.stamp
    DEPENDS venv requirements.txt
    COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_CURRENT_SOURCE_DIR}/requirements.txt requirements.txt
    COMMAND ./venv/bin/pip install -r requirements.txt --upgrade
)

# Build command line to run py.test.
set(PYTEST
    ${CMAKE_CURRENT_BINARY_DIR}/venv/bin/python2
    ${CMAKE_CURRENT_BINARY_DIR}/venv/bin/py.test
)


add_custom_target(Tests ALL
    DEPENDS venv.stamp
    SOURCES requirements.txt
)

add_test(NAME run_tests
    COMMAND ${PYTEST} ${CMAKE_CURRENT_SOURCE_DIR}/test_sample.py
)

Tried doing this with python3 venv and wasn't able to get it to work sadly. Running commands like this ./venv/bin/pip install -r requirements.txt --upgrade were trying to install globally.

# setup venv if it doesn't exist
IF (NOT EXISTS "${CMAKE_BINARY_DIR}/venv")
    FIND_PACKAGE(Python3)
    EXECUTE_PROCESS(COMMAND ${Python3_EXECUTABLE} "-m" "venv" "venv"
            WORKING_DIRECTORY ${CMAKE_BINARY_DIR})
    UNSET(${Python3_EXECUTABLE})
ENDIF ()
# activate python venv
SET(ENV{VIRTUAL_ENV} "${CMAKE_BINARY_DIR}/venv")
FIND_PACKAGE(Python3)

The following approach works fine with python 3:
https://discourse.cmake.org/t/possible-to-create-a-python-virtual-env-from-cmake-and-then-find-it-with-findpython3/1132