Convert DSpace Simplestats statistics to analysis-friendly CSV

create-simplestats-csv.xq

declare option output:method "csv";
declare option output:csv "header=yes, separator=comma";

declare function local:to-datestamp($raw_date){
  let $parts:=tokenize($raw_date," / ")
  return $parts[2] || '-' || $parts[1] || '-1'
  
};

declare function local:not-total($string) {
  let $status:= not($string eq "Total") and not($string eq "/ The entire DSpace")
  return $status
};

let $range:=//th[local:not-total(.) and not(@class)]

let $datestamps:=
  for $date in $range
    return local:to-datestamp($date)
    
let $items:=
<items>{for $item in //tr[position()>1]
  let $handle:=data($item/td/a/@href)
  let $counts:=
    for $count in $item/td[position()>1]
    count $c
    where $datestamps[$c]
    return 
    <stat date="{$datestamps[$c]}" count="{$count}"/>
  return
  
  <item>
  <handle>{$handle}</handle>
  {$counts}
  
  </item>
}</items>



let $csv:=
<csv>{
for $item in $items/item
  let $stats:=$item/stat
  for $stat in $stats
  return
  <entry>
  <handle>{data($item/handle)}</handle>
  <date>{data($stat/@date)}</date>
  <count>{data($stat/@count)}</count>
  </entry> 
}</csv>
return $csv