Configure global libraries in Jenkins (see https://jenkins.io/doc/book/pipeline/shared-libraries/) using a post-initialization script (see https://wiki.jenkins.io/display/JENKINS/Post-initialization+script)

addPipelineLibrary.groovy

import jenkins.plugins.git.GitSCMSource
import org.jenkinsci.plugins.workflow.libs.GlobalLibraries
import org.jenkinsci.plugins.workflow.libs.LibraryConfiguration
import org.jenkinsci.plugins.workflow.libs.SCMSourceRetriever

/*
 * add shared libraries
 * see https://jenkins.io/doc/book/pipeline/shared-libraries/
 */

GlobalLibraries globalLibraries = Jenkins.instance.getExtensionList(GlobalLibraries).first()

LibraryConfiguration myImplicitLibraryConfiguration = new LibraryConfiguration(
    "my-jenkins-lib",
    new SCMSourceRetriever(new GitSCMSource("<YOUR_LIB_GIT_URL>"))
)
myImplicitLibraryConfiguration.implicit = true
myImplicitLibraryConfiguration.defaultVersion = "master" // or commit or branch
myImplicitLibraryConfiguration.allowVersionOverride = false // pipelines may not override default version
myImplicitLibraryConfiguration.includeInChangesets = false // don not add library changes in pipline log

LibraryConfiguration myExplicitLibraryConfiguration = new LibraryConfiguration(
    "my-other-jenkins-lib",
    new SCMSourceRetriever(new GitSCMSource("<YOUR_OTHER_LIB_GIT_URL>"))
)
myExplicitLibraryConfiguration.implicit = false
myExplicitLibraryConfiguration.defaultVersion = "master" // or commit or branch
myExplicitLibraryConfiguration.allowVersionOverride = false // pipelines may not override default version
myExplicitLibraryConfiguration.includeInChangesets = false // don not add library changes in pipline log

globalLibraries.libraries = [myImplicitLibraryConfiguration, myExplicitLibraryConfiguration]

Jenkinsfile

@Library("my-other-jenkins-lib@other-version") _

pipeline {

    agent any

    environment {
        SECRET_TEXT = credentials("googleChatWebhookCommonSystemTestsStatus")
    }

    stages {
        stage("Use libraries") {
            steps {
                stepFromMyLib "as it was loaded implicitly"
                stepFromMyOtherLib "as it was loaded by @Library"
            }
        }
    }
}