CPF Validator in Brainfuck

CPF Validator in Brainfuck

CPF
>+
>++
>+++
>++++
>+++++
>++++++
>+++++++
>++++++++
>+++++++++

>>>>>>

Qty Digits
+++++++++

Flag Spot To Move CPF
<+>

Move CPF and add one
[<[<]<<<<[>>>>+<<<<-]>>>>+[>]<-]

Reset Flag Spot
<->

Add Logic For Big Loop
<<[<]<<<++

Start Big Loop
[

>>>>[>]>

Define the Multiplier
++++++++++

<<[<]>

Start Loop
[

Copy Next Digit
[<<+>>>[>]>>+<<<[<]>-]

Make a flag
+

[>]>>>>>

Define de Divider
+++++++++++

<<<

Make the multiplication
[<[<+>>>+<<-]<[>+<-]>>-]

Add the division in multiplication result
>>>[<+<+>>-]<<

Sub one time the multiplier
<<[<+>>>-<<-]<[>+<-]

>>>

Make the Mod and present only the mod
[>->+<[>]>[<+>-]<<[<]>-]>[-]

Move mod to next sum
>+[<<+>>-]<<-

Sub one in multiplier
<<-

<<[<]>

Remove flag
-

>

End Loop
]

Reset Multiplier
>[-]

<+>>+

Add One To Avoid 0
+>+

Copy the If B
[>+>+<<-]>[<+>-]<<

Make the if(A GorE B)
[->-[>]<<]
<[-
 <<+>>
]
<[-<
 <+++++++++++++>>>>>>>
 [<<<<<<<->>>>>>>-]
 <<<<<<
]

Reset If
>>>>[-]>>[-]

<<<<<<<

Move digits to correct spot
[[>>+<<-]<]

Add one in next multiply
>>>[>]>+

End Big Loop
<<[<]<<<-]

Remove the one extra in multiply
>>>>[>]>-

<<[<]>

Move back to start
[[<<<<<+>>>>>-]<<<<<->>>>>>]