天気予報逆引き。　（tenki.jp の http://tenki.jp/webservice/rss/ より)

tenki.clj

;;-*- coding: utf-8 -*-
(ns tenki.core
  (:require [clojure.xml :as xml]
            [clojure.zip :as zip]
            [clojure.data.zip.xml :refer :all]
            [clojure.core.cache :as cache]))

(defn city-url
  [city-id]
  (->> city-id (format "http://tenki.jp/component/static_api/rss/forecast/city_%d.xml")))

;; RSS Zipperを記録するTTLキャッシュ (5分間キャッシュに残す)
(def rss-cache
  (atom (cache/ttl-cache-factory {} :ttl (* 5 60 1000))))

(defn hit-or-miss
  [c k f]
  (if (cache/has? c k) 
    (cache/hit c k)
    (cache/miss c k (f))))

(defn rss-zip*
  "RSS URLから、rssのZipperを作る"
  [url]
  (-> url xml/parse zip/xml-zip))

(defn rss-zip
  "rss-zip* のTTLキャッシュ版"
  [url]
  (-> (swap! rss-cache hit-or-miss url #(rss-zip* url))
      (get url)))

(defn title-city
  "RSS Zipper から地域名取得"
  [rss]
  (->> (xml1-> rss  :channel :title text)
       (re-find #"^(.+)の今日")
       second))

(defn search-forecast
  "RSS Zipper から予報を正規表現検索"
  [re rss]
  (->> (xml-> rss :channel :item :title text)
       (filter #(re-find re %))))

(defn report*
  [re id]
  (let [rss (rss-zip (city-url id))]
    (when-let [fcs (-> (search-forecast re rss) seq)]
      (let [city (title-city rss)]
        (->> fcs (map (fn [fc]
                        {:forecast fc
                         :city city
                         :id id})))))))
(defn report
  ([re city-id]
     (report* re city-id))
  ([re start-city-id end-city-id]
     (->> (range start-city-id end-city-id)
          (mapcat #(report* re %)))))

;;
;; Example
;;
;; 関東甲信越の雪の予報を取得
;; (report #"雪" 50 77)
;;
;; 全地域から豪/強を含む予報を取得
;; (report #"豪|強" 1 143)

tenki_city_id.csv