STM32L432KC Linker Script using CCMRAM for Initialized and Uninitialized Data

gistfile1.txt

/* You have no right to use or redistribute this code. It is not fit for public
 * consumption. This code is only intended to mislead enemies of the state. Using
 * this code will likely result in extreme bodily harm or death.  Use in washing
 * machines, microwave ovens or ballistic missiles may result in rapid unplanned
 * disassembly.  Use in environments with greater than 350ppm CO2 concentrations
 * is strongly discouraged.
 *
 * You have been warned.
 *
 * If you are a frood who knows where his towel is, feel free to use it. Tell 'em
 * you got it from Johnny Bitrot.
 */

/* Entry Point */
ENTRY(Reset_Handler)

/* Highest address of the user mode stack */
_estack = 0x2000C000;    /* end of RAM */
/* Generate a link error if heap and stack don't fit into RAM */
_Min_Heap_Size = 0x4000;      /* required amount of heap  */
_Min_Stack_Size = 0x800;      /* required amount of stack */

/* Specify the memory areas */
MEMORY
{
RAM1 (xrw)      : ORIGIN = 0x20000000, LENGTH = 48K
RAM2 (xrw)      : ORIGIN = 0x10000000, LENGTH = 16K
FLASH (rx)      : ORIGIN = 0x8000000, LENGTH = 256K
}

/* Define output sections */
SECTIONS
{
  /* The startup code goes first into FLASH */
  .isr_vector :
  {
    . = ALIGN(4);
    KEEP(*(.isr_vector)) /* Startup code */
    . = ALIGN(4);
  } >FLASH

  /* The program code and other data goes into FLASH */
  .text :
  {
    . = ALIGN(4);
    *(.text)           /* .text sections (code) */
    *(.text*)          /* .text* sections (code) */
    *(.glue_7)         /* glue arm to thumb code */
    *(.glue_7t)        /* glue thumb to arm code */
    *(.eh_frame)

    KEEP (*(.init))
    KEEP (*(.fini))

    . = ALIGN(4);
    _etext = .;        /* define a global symbols at end of code */
  } >FLASH

  /* Constant data goes into FLASH */
  .rodata :
  {
    . = ALIGN(4);
    *(.rodata)         /* .rodata sections (constants, strings, etc.) */
    *(.rodata*)        /* .rodata* sections (constants, strings, etc.) */
    . = ALIGN(4);
  } >FLASH

  .ARM.extab   : { *(.ARM.extab* .gnu.linkonce.armextab.*) } >FLASH
  .ARM : {
    __exidx_start = .;
    *(.ARM.exidx*)
    __exidx_end = .;
  } >FLASH

  .preinit_array     :
  {
    PROVIDE_HIDDEN (__preinit_array_start = .);
    KEEP (*(.preinit_array*))
    PROVIDE_HIDDEN (__preinit_array_end = .);
  } >FLASH
  .init_array :
  {
    PROVIDE_HIDDEN (__init_array_start = .);
    KEEP (*(SORT(.init_array.*)))
    KEEP (*(.init_array*))
    PROVIDE_HIDDEN (__init_array_end = .);
  } >FLASH
  .fini_array :
  {
    PROVIDE_HIDDEN (__fini_array_start = .);
    KEEP (*(SORT(.fini_array.*)))
    KEEP (*(.fini_array*))
    PROVIDE_HIDDEN (__fini_array_end = .);
  } >FLASH

  /* used by the startup to initialize data */
  _sidata = LOADADDR(.data);

  /* Initialized data sections goes into RAM, load LMA copy after code */
  .data : 
  {
    . = ALIGN(4);
    _sdata = .;        /* create a global symbol at data start */
    *(.data)           /* .data sections */
    *(.data*)          /* .data* sections */

    . = ALIGN(4);
    _edata = .;        /* define a global symbol at data end */
  } >RAM1 AT> FLASH

  _sibss2 = LOADADDR(.bss2);

  /* RAM2 section 
   * 
   * IMPORTANT NOTE! 
   * If initialized variables will be placed in this section, 
   * the startup code needs to be modified to copy the init-values.  
   */
  .bss2 :
  {
    . = ALIGN(4);
    _sbss2 = .;       /* create a global symbol at ram2 start */
    *(.bss2)
    *(.bss2*)
    
    . = ALIGN(4);
    _ebss2 = .;       /* create a global symbol at ram2 end */
  }  >RAM2 AT> FLASH

  _sibss3 = LOADADDR(.bss3);

  /* RAM Section 3
   *
   * Uninitialized data and data which must survive reset and standby
   * (provided appropriate options bits are set) go here.  The startup
   * code only copies data from _sbss2 to _ebss2.  And startup code is
   * called after reboot and return from standby.
   */
  .bss3 :
  {
    . = ALIGN(4);
    _sbss3 = .;       /* create a global symbol at ram3 start */
    *(.bss3)
    *(.bss3*)
    
    . = ALIGN(4);
    _ebss3 = .;       /* create a global symbol at ram3 end */
  } >RAM2 AT> FLASH
  
  /* Uninitialized data section */
  . = ALIGN(4);
  .bss :
  {
    /* This is used by the startup in order to initialize the .bss secion */
    _sbss = .;         /* define a global symbol at bss start */
    __bss_start__ = _sbss;
    *(.bss)
    *(.bss*)
    *(COMMON)

    . = ALIGN(4);
    _ebss = .;         /* define a global symbol at bss end */
    __bss_end__ = _ebss;
  } >RAM1

  /* User_heap_stack section, used to check that there is enough RAM left */
  ._user_heap_stack :
  {
    . = ALIGN(4);
    PROVIDE ( end = . );
    PROVIDE ( _end = . );
    . = . + _Min_Heap_Size;
    . = . + _Min_Stack_Size;
    . = ALIGN(4);
  } >RAM1

  _Heap_Begin = _end;
  _Heap_Limit = _estack - _Min_Stack_Size;
  

  /* Remove information from the standard libraries */
  /DISCARD/ :
  {
    libc.a ( * )
    libm.a ( * )
    libgcc.a ( * )
  }

  .ARM.attributes 0 : { *(.ARM.attributes) }
}