recursive file traversal, in parallel!

find.pl6

#!./perl6-j
use v6;

sub MAIN($path = '.') {
    my $counter = 0;
    my $callback = sub ($file) {
        $counter++;
#        say $counter, "\t", $file.Str;
    };

    walk $path, $callback;
    say $counter;
}

sub walk($dir, &callback) {
    my $dirs   = Channel.new;
    my $files  = Channel.new;
    my $reader = start {
        callback($_) for $files.list;
        1;
    };
    $dirs.send($dir);
    my @file-readers;
    loop {
        my $f = $dirs.poll;

        unless ($f) {
            say "Got no element";
            @file-readers = @file-readers.grep: { .status ~~ Planned };
            if @file-readers {
                winner @file-readers { done * { } };
                next;
            }
            else {
                $f = $dirs.poll;
                unless $f {
                    $dirs.close;
                    last;
                }
            }
        }

        @file-readers.push: start {
            for dir($f) -> $path {
                if $path.d {
                    $dirs.send: $path;
                }
                else {
                    $files.send: $path;
                }
            }
        }
    }
    $files.close;
    await $reader;
}

# vim: ft=perl6