Version code and name generation using Gradle

Version code and name generation using Gradle

ext.makeVersionCode = { ->
    try {
        def code = new ByteArrayOutputStream()
        exec {
            commandLine 'git', 'rev-list', 'HEAD', '--count'
            standardOutput = code
        }
        return Integer.parseInt(code.toString().trim())
    }
    catch (ignored) {
        logger.error(ignored.printStackTrace())
        return -1
    }
}

ext.makeVersionNameRelease = { ->
    try {
        def lastTag = new ByteArrayOutputStream()
        exec {
            commandLine 'git', 'rev-list', '--tags', '--no-walk', '--max-count=1'
            standardOutput = lastTag
        }

        def lastCommits = new ByteArrayOutputStream()
        exec {
            commandLine 'git', 'rev-list', lastTag.toString().trim() + '..HEAD', '--count'
            standardOutput = lastCommits
        }

        def versionName = new ByteArrayOutputStream()
        exec {
            commandLine 'git', 'describe', '--tags', '--abbrev=0'
            standardOutput = versionName
        }

        return versionName.toString().trim() + '.' + lastCommits.toString().trim()
    }
    catch (ignored) {
        logger.error(ignored.printStackTrace())
        return null
    }
}

ext.currentBranch = { ->
    try {
        def currentBranch = new ByteArrayOutputStream()
        exec {
            commandLine 'git', 'rev-parse', '--abbrev-ref', 'HEAD'
            standardOutput = currentBranch
        }

        return currentBranch.toString().trim()
    }
    catch (ignored) {
        logger.error(ignored.printStackTrace())
        return null
    }
}

ext.makeVersionNameDebug = { ->
    return versionName + '/' + currentBranch
}

Usage:

apply from: 'URL_TO_RAW'

android {
    defaultConfig {
        versionCode makeVersionCode()
        versionName makeVersionNameRelease()
    }
}