Nexus 3 script delete images not downloaded since X months.

gistfile1.txt

import groovy.time.TimeCategory
import org.sonatype.nexus.repository.storage.Asset
import org.sonatype.nexus.repository.storage.Component
import org.sonatype.nexus.repository.storage.Query
import org.sonatype.nexus.repository.storage.StorageFacet

def repo = repository.repositoryManager.get("sq-docker")

StorageFacet storageFacet = repo.facet(StorageFacet)
def tx = storageFacet.txSupplier().get()
def cutoff
tx.begin()
try {
    use(TimeCategory) {
        cutoff = 1.year.ago
        log.info "Deleting all docker images (components) for which the manifest has not been downloaded since [${cutoff.format('yyyy-MM-dd HH:mm:ss')}]"
    }

    Iterable<Asset> assets = tx
            .findAssets(Query.builder()
            .where('content_type = ').param('application/vnd.docker.distribution.manifest.v2+json')
            .and('last_downloaded < ').param(cutoff.format("yyyy-MM-dd HH:mm:ss"))
            .build(), [repo])

    assets.each {
        if (it.componentId() != null) {
            Component image = tx.findComponent(it.componentId())
            log.info("Deleting image [${image.name()}:${image.version()}] last downloaded on [${it.lastDownloaded()}]")
            tx.deleteComponent(image)
        }
    }
} finally {
    tx.commit()
}

log.info("Finished deleting unused images components. Layers will be removed when the 'purge docker unused Images and manifests' and 'Compact blob store' tasks will run")

Hi where are you providing nexus URL reponame username and password

Hi where are you providing nexus URL reponame username and password

This script will be configured as a nexus script task. Authentication is not useful.
http://<nexus_server>/#admin/system/tasks -> Create task -> Admin - Execute script