Subclassing non-Moose classes example 3 - From http://blogs.perl.org/users/mark_a_stratman/2011/03/subclassing-tricky-non-moose-classes-constructor-problems.htm

Animal3.pm

# NOTE: This is simply an example of a legacy array-based object. 
#       I do not recommend using it.
package Animal3;
use strict;

our $NAME_INDEX = 0;

sub new {
	my $class = shift;
	my $self = [];
	$self->[$NAME_INDEX] = shift;
	bless $self, $class;
	return $self;
}

sub name {
	my $self = shift;
	if (@_) { $self->[$NAME_INDEX] = shift }
	return $self->[$NAME_INDEX];
}

1;

Camel.pm

package Camel;
use Moose;
use MooseX::NonMoose::InsideOut;
extends 'Animal3';

has 'humps' => ( is  => 'ro', isa => 'Num' );

sub FOREIGNBUILDARGS {
    my $class = shift;
    # We expect a hashref with 'name' and 'humps'.
    my $args = shift;

    # Give Animal3 what it wants: just the name, and nothing else.
    return $args->{name};
}

no Moose;
__PACKAGE__->meta->make_immutable;

example3.pl

#!/usr/bin/perl
use Modern::Perl;
use Camel;

my $c = Camel->new({ name => "Samuel Camel", humps => 2 });
say $c->name, " has ", $c->humps, " humps";