CreatePeopleToolsPTFProject.bat

@echo off
REM PeopleTools Object Type export script
REM Find object type numbers
REM Definition Type Selections on PeopleTools 8.54: Application Designer Developer's Guide - Appendix B
REM https://docs.oracle.com/cd/E55244_01/psft/acrobat/pt854tapd-b0714.pdf
REM example - To create a project via application designer containing all PTF objects (104=Test Definitions,105=Test Framework Test Cases)

set pside=E:\apps\psoft\PT85509\bin\client\winx86\pside.exe
set export_path=E:\TEMP\out\export
set log_path=E:\TEMP\out
set dbtype=ORACLE
set psuser=oprid
set pspwd=opridpass
set ouser=people
set opwd=peop1e
set srcdb=dbname
set def_type="104,105"
set prjname=MY_PTFTESTS

echo "############ Creating Project############"
REM Create the project, NOTE THIS WILL OVERWRITE THE EXISTING PROJECT!!!!!!!!!!!!
%pside% -CT %dbtype% -CS -CD %srcdb% -CO %psuser% -CP %pspwd% -CI %ouser% -CW %opwd% -PJR %prjname% -OBJ %def_type% -OVW 1 -LF %log_path%\CreateProject.log -HIDE -QUIET -SS NO -SN NO
if %errorlevel% neq 0 echo "############Job Failed at Creating Project############" & exit /b %errorlevel%
if %errorlevel% equ 0 echo "############Success at Creating Project############"

echo "############Exporting Project############"
REM Export the project to file
%pside% -HIDE -PJTF %prjname% -FP %export_path% -CT %dbtype% -CO %psuser% -CP %pspwd% -CI %ouser% -CW %opwd% -CD %srcdb% -QUIET -AF 0 -DDL 1 -PPL 0 -CFD 0 -CFF 0 -LF %log_path%\export.log
if %errorlevel% neq 0 echo "############Job Failed at Exporting Project############" & exit /b %errorlevel%
if %errorlevel% equ 0 echo "############Success at Exporting Project############"

REM projects can be imported with the command below, NOTE THIS WILL OVERWRITE THE EXISTING PROJECT!!!!!!!!!!!!
REM %pside% -CT %dbtype% -CS -CD %srcdb% -CO %psuser% -CP %pspwd% -CI %ouser% -CW %opwd% -PJFF %prjname% -FP %export_path% -LF %log_path%\import.log -CL 100 -AF 1 -DDL 0 -PPL 1 -HIDE -QUIET -SS NO -SN NO