libuv 0.11.25 with inet_pton6.patch

PKGBUILD

# $Id: PKGBUILD 109507 2014-04-15 09:32:10Z mtorromeo $
# Maintainer: Massimiliano Torromeo <massimiliano.torromeo@gmail.com>

pkgname=libuv
pkgver=0.11.25
pkgrel=1
pkgdesc="A new platform layer for Node.JS"
arch=('i686' 'x86_64')
url="https://github.com/joyent/libuv"
license=('custom')
depends=('glibc')
source=("https://github.com/joyent/libuv/archive/v$pkgver.tar.gz"
        "inet_pton6.patch::https://github.com/saghul/libuv/commit/55efde0b50644b60492c266cf3977ce1d6a6c851.patch")

prepare() {
        cd "$srcdir/$pkgname-$pkgver"
        patch -p1 -i "$srcdir/inet_pton6.patch"
}

build() {
        cd "$srcdir/$pkgname-$pkgver"
        ./autogen.sh
        ./configure --prefix=/usr
        make
}

check() {
        cd "$srcdir/$pkgname-$pkgver"
        make check
}

package() {
        cd "$srcdir/$pkgname-$pkgver"

        make DESTDIR="$pkgdir" install

        install -Dm644 LICENSE \
                "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
        install -Dm644 AUTHORS \
                "$pkgdir/usr/share/doc/$pkgname/AUTHORS"
        install -Dm644 README.md \
                "$pkgdir/usr/share/doc/$pkgname/README.md"
        install -Dm644 ChangeLog \
                "$pkgdir/usr/share/doc/$pkgname/ChangeLog"
}

sha256sums=('b95a3e5eca9554998b7423ee786205e52731e82e2d24cbbd4f65af763de542fb'
            '16a0d45147508a0ba25d1e2a2f4fb307150cf9ca65e38c364e53ea1ba54c0545')