AdvMessageInterceptor-mu.st

SystemOrganization addCategory: #AdvMessageInterceptor!

ProtoObject subclass: #AdvMessageInterceptor
	instanceVariableNames: 'originalObject'
	classVariableNames: ''
	poolDictionaries: ''
	category: 'AdvMessageInterceptor'!

!AdvMessageInterceptor class methodsFor: 'instance creation' stamp: 'mu 12/13/2014 21:20'!
on: anOriginalObject
	^self new xxxOriginalObject: anOriginalObject! !

!AdvMessageInterceptor methodsFor: 'system primitives' stamp: 'mu 12/13/2014 21:20'!
becomeForward: otherObject 
	"Primitive. All variables in the entire system that used to point
	to the receiver now point to the argument.
	Fails if either argument is a SmallInteger."

	(Array with: self)
		elementsForwardIdentityTo:
			(Array with: otherObject)! !

!AdvMessageInterceptor methodsFor: 'system primitives' stamp: 'mu 12/13/2014 21:20'!
doesNotUnderstand: aMessage 
	aMessage transcriptOn: originalObject.
	^aMessage sendTo: originalObject! !

!AdvMessageInterceptor methodsFor: 'actions' stamp: 'mu 12/13/2014 21:20'!
intercepted
	^self! !

!AdvMessageInterceptor methodsFor: 'actions' stamp: 'mu 12/13/2014 21:20'!
quitIntercepting
	self becomeForward: originalObject! !

!AdvMessageInterceptor methodsFor: 'accessing' stamp: 'mu 12/13/2014 21:20'!
xxxOriginalObject: anObject
	originalObject := anObject! !

!Message methodsFor: '*AdvMessageInterceptor-logging' stamp: 'mu 12/13/2014 23:20'!
transcriptOn: receiver
	Transcript cr; 
		show: ('a {1}({2}) >> {3}' format: {receiver class name. receiver identityHash. self selector})! !

!Object methodsFor: '*AdvMessageInterceptor-actions' stamp: 'mu 12/13/2014 23:32'!
intercepted
	^AdMessageInterceptor on: self
! !

"Developing interceptor in Smalltalk"
http://qiita.com/mumez/items/72272fac093a2aaabbee