メニュープログラム（ファイル名/URL対応）

ランチャー_v100.vbs

'Ver 1.00 2021/07/24 デスクトップに置いて、サクサク使えるメニューを作成する。
'
'[処理]
' ファイル名/Exeファイル/URL/ショートカットを開く
'
'[使い方]
' このファイル(ランチャー.vbs)をデスクトップに置く
'
'[注意]
' エンコードは、ANSI(Shift JIS)で保存すること。
'
Option Explicit
'System
Dim objFsys
Dim objWsh
Dim objFile
Dim wErr : wErr = 0
Dim i,j,k, wNo, wCnt
'Procedure
Dim wMenuList: wMenuList = ""
Dim wMenu(10)
Dim wLink(10)
Dim wMSG
Dim wFile
Dim wWinPath

'------------------- メニューを記述してください -------------------
wMenu(1) = "Yahoo"                : wLink(1) = "https://www.yahoo.co.jp/"
wMenu(2) = "Google"               : wLink(2) = "https://www.google.com/"
wMenu(3) = "電　卓"               : wLink(3) = "C:\Windows\System32\calc.exe"
wMenu(4) = ""                     : wLink(4) = ""
wMenu(5) = ""                     : wLink(5) = ""
wMenu(6) = ""                     : wLink(6) = ""
wMenu(7) = ""                     : wLink(7) = ""
wMenu(8) = ""                     : wLink(8) = ""
wMenu(9) = ""                     : wLink(9) = ""
wMenu(10) = ""                    : wLink(10) = ""

'------------------- メインプログラム -------------------

Set objFsys = CreateObject("Scripting.FileSystemObject")
Set objWsh  = CreateObject("WScript.Shell")

Call s_CreateMenuStr

Do
  wMSG = wMenuList & vbCrLf & vbCrLf & "1～10を入力してください。"
  wNo = InputBox(  wMSG, "メニュー", "")
  If IsNumeric(wNo) Then
    If wNo = 0 Then Exit Do
    '--- メニューを終了 ---

    '1 ～ 10番 を選択
    If wNo > 0 And wNo < 11 Then
      If wMenu(wNo) = "" And wLink(wNo) = "" Then
        'メニュー未登録
        wMSG = "メニューを登録してください。"
        msgbox wMSG ,vbOKOnly + vbExclamation,"確認"
      Else
        If Instr(wLink(wNo), "http") > 0 Then
          s_BrowserRun(wLink(wNo))
        Else
          Call s_RunFile(wLink(wNo))
        End If
      End If
    End If

  End If
Loop

Set objFile = Nothing  
Set objWsh  = Nothing

WScript.Quit
'------------------- 共通モジュール -------------------
'
' ブラウザを実行する。
'
Sub s_BrowserRun(qURL)
      objWsh.Run qURL, 3
End Sub

'
' ファイルを実行する。(パス中にスペースがある場合は、" で囲む)
'
Sub s_RunFile(qFile)
  If objFsys.FileExists(qFile) Then
    If Instr(qFile, " ") > 0 then
      wFile = """" & qFile & """"
      objWsh.Run wFile
    Else
      objWsh.Run qFile
    End If
  Else
    wMSG = "ファイルが、見つかりません。"
    msgbox wMSG ,vbOKOnly + vbExclamation,"確認"
  End If
End Sub
'
' メニュー文字列を作成する。
'
Sub s_CreateMenuStr()
  For i = 1 to 10
    wMenuList = wMenuList & Right(" " & i, 2) & " : " & wMenu(i) & vbCrLf  & vbCrLf 
  Next 
End Sub