An ImageJ macroset with a tool that places dots with colors reflecting their z position and slice navigation that adjusts dot size to according to distance to the current slice.

zColored_dzSized_Dots.ijm

var sizes = newArray("Extra Large","Large","Medium","Small","Tiny");

macro "Z-Colored_Dots Tool - Cc0co1166C00co5366C0c0o5866Cc00o8a66" {
   roiManager("Associate", false);   
   r=newArray(256);
   for (i=0;i<r.length;i++) {
      r[i] = floor(127*(1+sin(2*PI*i/256)));
   }
   g=Array.copy(r);
   b=Array.copy(r);
   Array.rotate(g, 80);
   Array.rotate(b, 160);
   getCursorLoc(x, y, z, flags);
   makePoint(x,y);
   i = floor(255*(z+1)/nSlices);
   col = toHex(r[i]<<16+g[i]<<8+b[i]);
   while(lengthOf(col)<6) {col="0"+col;};
   run("Properties... ", "stroke=#"+col+" point=Dot size=[Extra Large]");   
   roiManager('add');
   roiManager("Show None");
   roiManager("Show All");
}

macro "next slice [q]" {
   run("Next Slice [>]");
   resizeDots();
}

macro "previous slice [w]" {
   run("Previous Slice [<]");
   resizeDots();
}

function resizeDots() {
   id=getImageID;
   cs=getSliceNumber();
   setBatchMode(1);
   newImage("Untitled", "8-bit ramp", 1, 1, nSlices);
   n = roiManager('count');
   for (i=0; i<n; i++) {
      roiManager('select', i);
      sn = getSliceNumber();
      size = abs(cs-sn);
      if (size<0) size =0;
      if (size>4) size =4;
      run("Properties... ", "size=["+sizes[size]+"]");   
   }
   selectImage(id);
   setBatchMode(0);
   setSlice(cs);
}