abstract build macro adding compare ops

AbstractCompare.hx

import haxe.macro.Context;
import haxe.macro.Expr;

class AbstractCompare
{
    public static function build():Array<Field>
    {
        var ab = switch (Context.getLocalType())
        {
            case TInst(_.get() => {kind: KAbstractImpl(a)}, _):
                a.get();
            default:
                throw new Error("AbstractCompare can only be used on abstracts", Context.currentPos());
        }

        var ct = TPath({pack: ab.pack, name: ab.name});
        var ctReal = haxe.macro.TypeTools.toComplexType(ab.type);

        var cls = macro class A {
            @:impl @:op(A < B) function lt(self:$ctReal, other:$ct):Bool;
            @:impl @:op(A <= B) function lte(self:$ctReal, other:$ct):Bool;
            @:impl @:op(A > B) function gt(self:$ctReal, other:$ct):Bool;
            @:impl @:op(A >= B) function gte(self:$ctReal, other:$ct):Bool;
        }

        var fields = Context.getBuildFields();
        fields = fields.concat(cls.fields);
        return fields;
    }
}