Code example for https://groups.google.com/forum/#!topic/haxelang/yNIkCx7w0t4

Main.hx

class Main {
    static function main() {
        var s = new Signature<Int->Void>();
    }
}

main.js

// Generated by Haxe
(function () { "use strict";
var Main = function() { };
Main.main = function() {
	var s = "Int -> Void";
};
Main.main();
})();

Signature.hx

#if macro
import haxe.macro.Context;
import haxe.macro.Expr;
import haxe.macro.Type;
using haxe.macro.Tools;
#end

#if !macro
@:genericBuild(Signature.build())
#end
@:dce
class Signature<T> {
#if macro
    static function build():ComplexType {
        var typeString = switch (Context.getLocalType()) {
            case TInst(_, [type]): type.toString();
            default:
                throw false;
        }
        
        var pos = Context.currentPos();
        var name = "Signature$" + typeString;
        var ctor = {
            pos: pos,
            name: "new",
            kind: FFun({
                args: [],
                ret: null,
                expr: macro this = $v{typeString}
            }),
            access: [APublic, AInline],
        };

        Context.defineType({
            pos: pos,
            pack: [],
            name: name,
            kind: TDAbstract(macro : String, null, [macro : String]),
            fields: [ctor],
            meta: [{name: ":dce", pos: pos}]
        });

        return TPath({pack: [], name: name});
    }
#end
}