Example for https://github.com/HaxeFoundation/haxe/issues/4313

FunctionArgMacro.hx

import haxe.macro.Context;
import haxe.macro.Expr;

class FunctionArgMacro {
    macro static function build():Array<Field> {
        var fields = Context.getBuildFields();
        for (field in fields) {
            switch (field.kind) {
                case FFun(fun):
                    var checks = [];
                    for (arg in fun.args) {
                        switch (arg.type) {
                            case macro : String:
                                for (m in arg.meta) {
                                    switch (m.name) {
                                        case "notNullOrEmpty":
                                            checks.push(macro if ($i{arg.name} == null) throw $v{arg.name + " is null"});
                                            checks.push(macro if ($i{arg.name}.length == 0) throw $v{arg.name + " is empty"});
                                    }
                                }
                            default:
                        }
                    }
                    fun.expr = macro {
                        $b{checks};
                        ${fun.expr};
                    }
                default:
            }
        }
        return fields;
    }
}

Main.hx

@:build(FunctionArgMacro.build())
class Main {
    static function main() {
    }

    static function greet(@notNullOrEmpty who:String) {
        trace('Hi, $who!');
    }
}

main.js

Main.greet = function(who) {
	if(who == null) {
		throw new js__$Boot_HaxeError("who is null");
	}
	if(who.length == 0) {
		throw new js__$Boot_HaxeError("who is empty");
	}
	console.log("Hi, " + who + "!");
};