EnumAbstractMacro.hx

import haxe.macro.Context;
import haxe.macro.Expr;

class EnumAbstractMacro
{
    public static function build():Array<Field>
    {
        var fields = Context.getBuildFields();

        var values = [];

        for (field in fields)
        {
            if (!hasMeta(field.meta, ":enum") || !hasMeta(field.meta, ":impl"))
                continue;

            switch (field.kind)
            {
                case FVar(_, {expr: ECast(e, _)}):
                    values.push(e);
                default: throw false;
            }
        }

        fields.push({
            name: "validValues",
            access: [APublic, AStatic],
            pos: Context.currentPos(),
            kind: FVar(null, macro $a{values})
        });

        return fields;
    }

    static function hasMeta(meta:Metadata, name:String):Bool
    {
        for (m in meta)
        {
            if (m.name == name)
                return true;
        }
        return false;
    }
}

MyEnum.hx

@:build(EnumAbstractMacro.build())
@:enum abstract MyEnum(Int)
{
    var A = 1;
    var B = 2;
    var C = 3;
}