Type params syntax sugar.

Main.hx

class Main {
    static function main() {
        var event:MapChangeEvent<Map<String,Int>>;
        $type(event.key); // String
        $type(event.value); // Int
    }
}

MapChangeEvent.hx

@:genericBuild(MapChangeEventMacro.build())
class MapChangeEvent<MapType> {}

class MapChangeEventImpl<TSource, TKey, TValue> {
    public var source:TSource;
    public var key:TKey;
    public var value:TValue;
}

MapChangeEventMacro.hx

import haxe.macro.Expr;
import haxe.macro.Context;
import haxe.macro.Type;
using haxe.macro.Tools;

class MapChangeEventMacro {
    static function build():ComplexType {
        return switch (Context.getLocalType()) {
            case TInst(_, [mapType]):
                switch (mapType.follow()) {
                    case TAbstract(_.get() => {pack: [], name: "Map"}, [keyType, valueType]):
                        return TPath({
                            pack: [],
                            name: "MapChangeEvent",
                            sub: "MapChangeEventImpl",
                            params: [
                                TPType(mapType.toComplexType()),
                                TPType(keyType.toComplexType()),
                                TPType(valueType.toComplexType()),
                            ],
                        });
                    default:
                        throw false;
                }
            default:
                throw false;
        }
    }
}